10HOME:? TAB(12); "WUMPUS":?:DIM s(20, 3):INPUT "INSTRUCTIONS? (y OR n) "; i$:?:IF LEFT$(i$, 1)<>"y" GOTO 30
20GOSUB 460
30REM          - CHOOSE AND SET UP CAVE.
40GOSUB 1370
50IF n=1 THEN GOSUB 2000:GOSUB 1480
60IF n=2 THEN GOSUB 2020:GOSUB 1550
70IF n=3 THEN GOSUB 2040:GOSUB 1620
80IF n=4 THEN GOSUB 2060:GOSUB 1690
90IF n=5 THEN GOSUB 2090:GOSUB 1760
100IF n=6 THEN GOSUB 2130:GOSUB 1830
110IF n=7 THEN GOSUB 2150:GOSUB 1900
120DEF FN a(x)=INT(20*RND(1))+1:DEF FN b(x)=INT(3*RND(1))+1:DEF FN c(x)=INT(4*RND(1))+1
130REM          - LOCATE L ARRAY ITEMS
140REM          1-YOU, 2-WUMPUS,3&4-PITS,5&6-BATS
150DIM l(6), m(6)
160FOR j=1 TO 6
170 l(j)=FN a(0): m(j)=l(j):NEXT j
180REM          - CHECK FOR CROSSOVERS (IE l(1)=l(2) ETC)
190FOR j=1 TO 6:FOR k=j TO 6:IF j=k GOTO 220
210IF l(j)=l(k) GOTO 170
220NEXT k:NEXT j
230REM        SET # ARROWS
240 a=5: l=l(1)
250REM        - RUN THE GAME
260? "HUNT THE WUMPUS!":?:? "PRESS R WHEN READY":GET dummy$:GOSUB 6000
270REM        - HAZARDS WARNINGS AND LOCATION
280GOSUB 650
290REM        - MOVE OR SHOOT
300GOSUB 730:ON o GOTO 320, 350
310REM        SHOOT
320GOSUB 780:IF f=0 GOTO 300
330GOTO 360
340REM        MOVE
350GOSUB 1110:IF f=0 GOTO 280
360IF f>0 GOTO 400
370REM        LOSE
380? "HA HA HA - YOU LOSE!":GOTO 410
390REM        WIN
400? "HEE HEE HEE - THE WUMPUS'LL":? "GET YOU NEXT TIME!!"
410FOR j=1 TO 6: l(j)=m(j):NEXT j
420INPUT "PLAY AGAIN? "; i$:IF LEFT$(i$, 1)<>"y" GOTO 1990
430INPUT "SAME CAVE? "; i$:IF LEFT$(i$, 1)<>"y" GOTO 1370
440INPUT "SAME SET-UP? "; i$:IF LEFT$(i$, 1)<>"y" GOTO 160
450GOTO 240
460REM        - INSTRUCTIONS
470? "WELCOME TO WUMPUS":?:? "INSTRUCTIONS WILL PAUSE. WHEN":? "YOU'RE READY TO GO ON, PRESS R":?:GET dummy$
480? " THE WUMPUS LIVES IN A CAVE OF":? "20 ROOMS, EACH WITH 3 TUNNELS":? "GOING TO OTHER ROOMS. YOU HAVE"
490? "A CHOICE OF CAVES TO PLAY IN.":? "SOME CAVES ARE EASIER.":?:GET dummy$
500? "  THE HAZARDS ARE:":?:? "BOTTOMLESS PITS - 2 ROOMS HAVE":? "THEM. IF YOU GO THERE YOU FALL"
510? "INTO THE PIT (AND LOSE!)":?:GET dummy$
520? "SUPERBATS - TWO ROOMS HAVE":? "THEM. IF YOU GO THERE, A BAT":? "GRABS YOU AND TAKES YOU TO AN-"
530? "OTHER ROOM AT RANDOM.":?:GET dummy$
540? "WUMPUS - THE WUMPUS IS NOT":? "BOTHERED BY HAZARDS. HE HAS":? "SUCKER FEET AND IS TOO BIG FOR"
550? "A BAT TO LIFT.":?:GET dummy$:? "USUALLY HE IS ASLEEP. 2 THINGS":? "WAKE HIM UP: YOU ENTERING HIS"
560? "ROOM OR YOU SHOOTING AN ARROW.":?:GET dummy$:? "IF THE WUMPUS WAKES, HE MOVES"
570? "1 ROOM (75%) OR HE STAYS STILL":? "(25%). THEN IF HE IS WHERE YOU":? "ARE, HE EATS YOU UP (YOU LOSE!)":?:GET dummy$
580? "EACH TURN YOU MAY MOVE 1 ROOM":? "OR SHOOT AN ARROW. YOU HAVE 5:":? "WHEN YOU RUN OUT, YOU LOSE.":?:GET dummy$
590? "TO AIM, TELL ADAM THE ROOM YOU":? "WANT THE ARROW TO GO TO. IF IT":? "CAN'T (NO TUNNEL) IT MOVES AT"
600? "RANDOM TO THE NEXT ONE. IF IT":? "HITS THE WUMPUS, YOU WIN.":? "IF IT HITS YOU, YOU LOSE.":?:GET dummy$
610? "  WHEN YOU ARE ONE ROOM FROM":? "WUMPUS OR HAZARD, ADAM'LL SAY:":?:? "WUMPUS - 'I SMELL A WUMPUS'"
620? "BATS - 'BATS NEARBY'":? "PIT - 'I FEEL A DRAFT'":?:GET dummy$:? "THE CAVES ARE:":?:? "1 - DODECAHEDRON"
630? "2 - MOEBIUS STRIP":? "3 - STRING OF BEADS":? "4 - HEX NETWORK":? "5 - DENDRITE WITH DEGENERACIES"
640? "6 - ONE-WAY LATTICE":? "7 - MAKE YOUR OWN CAVE":?:GET dummy$:? "HAPPY HUNTING!":?:RETURN
650REM       
660?:FOR j=2 TO 6:FOR k=1 TO 3:IF s(l(1), k)<>l(j) GOTO 710
670ON j-1 GOTO 680, 690, 690, 700, 700
680? "I SMELL A WUMPUS!":GOTO 710
690? "I FEEL A DRAFT!":GOTO 710
700? "BATS NEARBY!"
710NEXT k:NEXT j:? "YOU ARE IN ROOM "; l(1); 
720? " TUNNELS LEAD TO "; s(l, 1); " "; s(l, 2); " "; s(l, 3): u=s(l, 1): v=s(l, 2): w=s(l, 3):RETURN
730REM        - CHOOSE OPTION
740INPUT "SHOOT OR MOVE? (s OR m) "; i$:IF LEFT$(i$, 1)<>"s" GOTO 760
750 o=1:RETURN
760IF LEFT$(i$, 1)<>"m" GOTO 740
770 o=2:RETURN
780REM        - ARROW ROUTINE
790 f=0
800REM        - PATH OF ARROW
810 l=l(1)
820INPUT "THRU HOW MANY ROOMS? (1-5) "; j9:IF j9<1 OR j9>5 THEN 820
830FOR k=1 TO j9
840INPUT "ROOM # "; p(k):IF k<=2 THEN 870
850IF p(k)<>p(k-2) THEN 870
860? "ARROWS AREN'T THAT CROOKED - TRY ANOTHER ROOM":GOTO 840
870NEXT k
880REM        - SHOOT ARROW
890GOSUB 6190: a=a-j9: a9=l(1):FOR k=1 TO j9:FOR k1=1 TO 3:IF s(a9, k1)=p(k) GOTO 1020
900NEXT k1
910REM        - NO TUNNEL FOR THE ARROW
920 a9=s(a9, FN b(1)):GOTO 1030
930NEXT k:? "MISSED"
940REM        - MOVE WUMPUS
950GOSUB 1070
960REM        - AMMO CHECK
970IF a>0 GOTO 1000
980? "YOU HAVE USED ALL OF YOUR ARROWS."
990 f=-1
1000RETURN
1010REM        - SEE IF ARROW IS AT l(1) or l(2)
1020 a9=p(k)
1030IF a9<>l(2) GOTO 1050
1040GOSUB 6345:? "AHA! YOU GOT THE WUMPUS!": f=1:RETURN
1050IF a9<>l(1) GOTO 930
1060GOSUB 6470:? "OUCH! ARROW GOT YOU!":GOTO 990
1070REM        - MOVE WUMPUS ROUTINE
1080 k=FN c(0):IF k=2 OR k=4 THEN 1100
1090GOSUB 7590:? "TSK TSK TSK - WUMPUS GOT YOU!": f=-1:GOTO 370
1100GOSUB 7490:RETURN
1110REM        - MOVE ROUTINE
1120 f=0:GOTO 1150
1130? "ERROR  "; 
1140INPUT z9:? ""; 
1150INPUT "WHERE TO? "; l:IF l<1 OR l>20 OR ABS(l)<>INT(l) GOTO 1130
1160FOR k=1 TO 3
1170REM                        - CHECK IF LEGAL MOVE
1180IF s(l(1), k)=l GOTO 1240
1190NEXT k:IF l=l(1) GOTO 1240
1200? "NOT POSSIBLE - "; 
1210INPUT z9:? ""; 
1220GOTO 1150
1230REM                        - CHECK FOR HAZARDS
1240 l(1)=l:GOSUB 6000
1250REM                        - WUMPUS
1260IF l<>l(2) GOTO 1310
1270? "OOP! BUMPED A WUMPUS!"
1280REM                        - MOVE A WUMPUS
1290GOSUB 1080:IF f=0 GOTO 1310
1300REM                        -PIT
1310IF l<>l(3) AND l<>l(4) GOTO 1340
1320FOR i=1 TO 5:? "YYYIIIEEEE...FELL IN A PIT!":NEXT i:GOSUB 6570: f=-1:RETURN
1330REM                        - BATS
1340IF l<>l(5) AND l<>l(6) GOTO 1360
1350GOSUB 6900: l=FN a(1):GOTO 1240
1360RETURN
1370REM                        - SELECT CAVE
1380GOTO 1400
1390? "ERROR!"
1400INPUT "CAVE #(1-7) ?"; n:?:IF n<1 OR n>7 THEN 1390
1410RETURN
1480REM                           - DODECAHEDRON
1490FOR j=1 TO 20:FOR k=1 TO 3:READ s(j, k):NEXT k:NEXT j
1500DATA                         2,5,8,1,3,10,2,4,12,3,5,14,1,4,6
1510DATA                         5,7,15,6,8,17,1,7,9,8,10,18,2,9,11
1520DATA             10,12,19,3,11,13,12,14,20,4,13,15,6,4,16
1530DATA              15,17,20,7,16,18,9,17,19,11,18,20,13,16,19
1540RETURN
1550REM                      - MOEBIUS STRIP
1560FOR b1=1 TO 1:FOR b2=1 TO 60:READ b0:NEXT b2:NEXT b1
1570DATA                      20,2,3,19,1,4,1,4,5,2,3,6,3,6,7
1580DATA                      4,5,8,5,8,9,6,7,10,7,10,11,8,9,12
1590DATA             9,12,13,10,11,14,11,14,15,12,13,16,12,16,17
1600DATA                                                                14,15,18,15,18,19,16,17,20,2,17,20,1,18,19
1610GOSUB 1970:RETURN
1620REM                       - STRING OF BEADS
1630FOR b1=1 TO 2:FOR b2=1 TO 60:READ b0:NEXT b2:NEXT b1
1640DATA                      2,3,20,1,3,4,1,2,4,2,3,5,4,6,7
1650DATA                      5,7,8,5,6,8,6,7,9,8,10,11,9,11,12
1660DATA             9,10,12,10,11,13,12,14,15,13,15,16,13,14,16
1670DATA             14,15,17,16,18,19,17,19,20,17,18,20,1,18,19
1680GOSUB 1970:RETURN
1690REM                     - HEX NETWORK ON TORUS
1700FOR b1=1 TO 3:FOR b2=1 TO 60:READ b0:NEXT b2:NEXT b1
1710DATA                     6,10,16,6,7,17,7,8,18,8,9,19,9,10,20
1720DATA                     1,2,15,2,3,11,3,4,12,4,5,13,5,6,14
1730DATA                     7,16,20,8,16,17,9,17,18,10,18,19,6,19,20
1740DATA                     1,11,12,2,12,13,3,13,14,4,14,15,5,11,15
1750GOSUB 1970:RETURN
1760REM      -DENDRITE WITH DEGENERACIES
1770FOR b1=1 TO 4:FOR b2=1 TO 60:READ b0:NEXT b2:NEXT b1
1780DATA       1,1,5,2,2,5,3,3,6,4,4,6,1,2,7
1790DATA       3,4,7,5,6,10,8,9,9,8,8,10,7,9,11
1800DATA       10,13,14,12,13,13,11,12,12,11,15,16,14,17,18
1810DATA       14,19,20,15,17,17,15,18,18,16,19,19,16,20,20
1820GOSUB 1970:RETURN
1830REM      -ONE-WAY LATTICE
1840FOR b1=1 TO 5:FOR b2=1 TO 60:READ b0:NEXT b2:NEXT b1
1850DATA       5,4,8,1,5,6,2,6,7,3,7,8,8,9,12
1860DATA       5,9,10,6,10,11,7,11,12,12,13,16,9,13,14
1870DATA       10,14,15,11,15,16,16,17,20,13,17,18,14,18,19
1880DATA       15,19,20,1,4,20,1,2,17,2,3,18,3,4,19
1890GOSUB 1970:RETURN
1900REM                      - YOUR OWN CAVE
1910FOR j=1 TO 20
1920? "ROOM #"; j:INPUT "CONNECTS WITH (1) ROOM # ? "; x
1930INPUT "CONNECTS WITH (2) ROOM # ? "; y:INPUT "CONNECTS WITH (3) ROOM # ? "; z: s(j, 1)=x: s(j, 2)=y: s(j, 3)=z
1940FOR k=1 TO 3:IF s(j, k)>0 AND s(j, k)<21 THEN 1950
1950? "***** ERROR!!!!!":GOTO 1920
1960NEXT k:NEXT j:RETURN
1970REM                         - INPUT CAVE
1980FOR j=1 TO 20:FOR k=1 TO 3:READ s(j, k):NEXT k:NEXT j:RETURN
1990TEXT:END
2000? TAB(10); "DODECAHEDRON":?:? "THE ROOMS OF THIS CAVE ARE ON ":? "A 12-SIDED OBJECT. EACH SIDE "
2010? "FORMS A PENTAGON. THE ROOMS ":? "ARE AT THE PENTAGONS' CORNERS.":?:RETURN
2020? TAB(8); "MOEBIUS STRIP":?:? "THIS CAVE IS 2 ROOMS WIDE AND ":? "10 ROOMS AROUND (LIKE A BELT)."
2030? "THERE IS A 1/2 TWIST SOMEWHERE":?:RETURN
2040? TAB(8); "STRING OF BEADS":?:? "5 BEADS IN A CIRCLE. EACH BEAD":? "IS A DIAMOND WITH A VERTICAL "
2050? "CROSS-BAR. THE RIGHT AND LEFT ":? "CORNERS LEAD TO NEIGHBORING":? "BEADS. THIS ONE IS DIFFICULT.":?:RETURN
2060? TAB(7); "HEX NUT ON TORUS":?:? "IMAGINE A HEX TILE FLOOR. TAKE":? "A RECTANGLE WITH TWENTY POINTS"
2070? "(INTERSECTIONS) INSIDE (4x4).":? "JOIN RIGHT AND LEFT SIDES TO":? "MAKE A CYLINDER. THEN JOIN TOP"
2080? "AND BOTTOM TO FORM A TORUS -":? "DOUGHNUT. HAVE FUN IMAGINING IT":?:RETURN
2090? TAB(4); "DENDRITE WITH DEGENERACIES":?:? "PULL A PLANT FROM THE GROUND.":? "THE ROOTS AND BRANCHES FORM A"
2100? "DENDRITE - I.E., THERE ARE NO":? "LOOPING PATHS. DEGENERACY IS:":? "A) SOME ROOMS CONNECT TO THEM-"
2110? "SELVES AND B) SOME ROOMS HAVE":? "MORE THAN 1 TUNNEL TO THE SAME":? "OTHER ROOM, I.E., 12 HAS TWO"
2120? "TUNNELS TO 13.":RETURN
2130? TAB(7); "ONE-WAY LATTICE":?:? "ALL TUNNELS GO 1 WAY ONLY.":? "TO RETURN, YOU MUST GO AROUND"
2140? "THE CAVE (ABOUT 5 MOVES).":?:RETURN
2150? TAB(7); "MAKE YOUR OWN CAVE":?:? "YOU WILL BE ASKED THE ROOMS":? "NEXT TO EACH ROOM IN THE CAVE.":?:RETURN
6000GR
6010IF l(1)=1 OR l(1)=8 OR l(1)=15 THEN  e=6
6015IF l(1)=1 OR l(1)=8 OR l(1)=15 THEN  g=4
6020IF l(1)=2 OR l(1)=9 OR l(1)=16 THEN  e=11
6025IF l(1)=2 OR l(1)=9 OR l(1)=16 THEN  g=9
6030IF l(1)=3 OR l(1)=10 OR l(1)=17 THEN  e=7
6035IF l(1)=3 OR l(1)=10 OR l(1)=17 THEN  g=2
6040IF l(1)=4 OR l(1)=11 OR l(1)=18 THEN  e=3
6045IF l(1)=4 OR l(1)=11 OR l(1)=18 THEN  g=1
6050IF l(1)=5 OR l(1)=12 OR l(1)=19 THEN  e=13
6055IF l(1)=5 OR l(1)=12 OR l(1)=19 THEN  g=8
6060IF l(1)=6 OR l(1)=13 OR l(1)=20 THEN  e=12
6065IF l(1)=6 OR l(1)=13 OR l(1)=20 THEN  g=7
6070IF l(1)=7 OR l(1)=14 THEN  e=14
6075IF l(1)=7 OR l(1)=14 THEN  g=7
6090COLOR =e
6100 a=0: b=38: c=0:FOR i=1 TO 3:FOR j=1 TO 2:GOSUB 6170:NEXT j:GOSUB 6182:NEXT i
6110 d=19:FOR i=1 TO 2:FOR j=1 TO 2:GOSUB 6180:NEXT j:GOSUB 6182:NEXT i:FOR i=1 TO 2:FOR j=1 TO 2
6120GOSUB 6170:NEXT j:GOSUB 6182:NEXT i: d=d-1:COLOR =g:FOR i=1 TO 4:GOSUB 6170:NEXT i
6130FOR i=1 TO 4:GOSUB 6180:NEXT i:FOR i=1 TO 4:GOSUB 6170:NEXT i:COLOR =e: a=a-1: b=b+1: d=d+1
6140FOR i=1 TO 2:FOR j=1 TO 2:GOSUB 6170:NEXT j:GOSUB 6184:NEXT i:FOR i=1 TO 2:FOR j=1 TO 2
6150GOSUB 6180:NEXT j:GOSUB 6184:NEXT i:FOR i=1 TO 3:FOR j=1 TO 2:GOSUB 6170:NEXT j:GOSUB 6184:NEXT i:RETURN
6170VLIN a, b AT c: c=c+1:RETURN
6180VLIN a, d AT c: c=c+1:RETURN
6182 a=a+1: b=b-1:RETURN
6184 a=a-1: b=b+1:RETURN
6190REM                   SHOOT ARROW
6200IF p(1)=u THEN 6240
6210IF p(1)=w THEN 6270
6220 a=20: b=39:FOR j=1 TO 3:GOSUB 6290:GOSUB 6295:NEXT j:GOSUB 6290:GOSUB 6310
6225FOR j=1 TO 3:GOSUB 6290:GOSUB 6300:NEXT j
6230FOR j=1 TO 6:GOSUB 6290:GOSUB 6310:NEXT j:RETURN
6240 a=20: b=39:FOR j=1 TO 2:GOSUB 6290:GOSUB 6295:NEXT j:GOSUB 6290:GOSUB 6310:GOSUB 6290:GOSUB 6300
6245GOSUB 6290:GOSUB 6320:FOR j=1 TO 4
6250GOSUB 6290: a=a-1: b=b+1:NEXT j:FOR j=1 TO 4:GOSUB 6290:GOSUB 6320:NEXT j:GOSUB 6290:GOSUB 6300:GOSUB 6290
6255GOSUB 6320:FOR j=1 TO 2:GOSUB 6290:GOSUB 6300:NEXT j
6260FOR j=1 TO 4:GOSUB 6290:GOSUB 6310:NEXT j:FOR j=1 TO 2:GOSUB 6290:GOSUB 6300:NEXT j:GOSUB 6290:GOSUB 6310:RETURN
6270 a=20: b=39:FOR j=1 TO 2:GOSUB 6290:GOSUB 6295:NEXT j:FOR j=1 TO 2:GOSUB 6290:GOSUB 6340
6275NEXT j:FOR j=1 TO 2:GOSUB 6290:GOSUB 6295
6280NEXT j:FOR j=1 TO 2:GOSUB 6290:GOSUB 6340:NEXT j:FOR j=1 TO 5
6285GOSUB 6290:GOSUB 6295:NEXT j:FOR j=1 TO 5:GOSUB 6290:GOSUB 6310:NEXT j:RETURN
6290COLOR =15:FOR i=1 TO 6:PLOT a, b:NEXT i:COLOR =0:PLOT a, b:RETURN
6295 a=a+1: b=b-1:RETURN
6300 a=a-1: b=b-1:RETURN
6310 b=b-1:RETURN
6320 a=a-1:RETURN
6340 a=a+1: b=b+1:RETURN
6345REM                WUMPUS SHOT
6350IF p(1)=u THEN 6390
6360IF p(1)=w THEN 6430
6370FOR i=1 TO 5:FOR k=1 TO 6:COLOR =15: a=19: b=31: c=18:FOR j=1 TO 4:GOSUB 6460:NEXT j:NEXT k
6380COLOR =0: a=19: b=31: c=18:FOR j=1 TO 4:GOSUB 6460:NEXT j:FOR k=1 TO 9:NEXT k:NEXT i:RETURN
6390FOR i=1 TO 5:FOR k=1 TO 6
6400COLOR =15: a=20: b=35: c=6:FOR j=1 TO 2:GOSUB 6460:NEXT j: b=b-1:FOR j=1 TO 2:GOSUB 6460
6410NEXT j:NEXT k:COLOR =0: a=20: b=35: c=6:FOR j=1 TO 2:GOSUB 6460:NEXT j
6420 b=b-1:FOR j=1 TO 2:GOSUB 6460:NEXT j:FOR k=1 TO 9:NEXT k:NEXT i:RETURN
6430FOR i=1 TO 5:FOR k=1 TO 6:COLOR =15: a=19: b=34: c=30:FOR j=1 TO 2:GOSUB 6460:NEXT j: b=b+1
6440FOR j=1 TO 2:GOSUB 6460:NEXT j:NEXT k:COLOR =0: a=19: b=34: c=30:FOR j=1 TO 2:GOSUB 6460
6450NEXT j: b=b+1:FOR j=1 TO 2:GOSUB 6460:NEXT j:FOR k=1 TO 9:NEXT k:NEXT i:RETURN
6460VLIN a, b AT c: c=c+1:RETURN
6470REM                SHOOT SELF
6480 a=6: b=30:FOR j=1 TO 3:GOSUB 6340:NEXT j:FOR j=1 TO 3:GOSUB 6315:NEXT j:FOR j=1 TO 2
6490GOSUB 6340:NEXT j:GOSUB 6325:GOSUB 6340:FOR j=1 TO 3:GOSUB 6325:NEXT j:FOR j=1 TO 4:GOSUB 6290
6500NEXT j:GOSUB 6325:GOSUB 6340:GOSUB 6315:FOR j=1 TO 3:GOSUB 6330:NEXT j
6510FOR i=1 TO 5:FOR k=1 TO 3:COLOR =15: a=33: b=39: c=20:FOR j=1 TO 3:GOSUB 6560:NEXT j
6520GOSUB 6550: a=a-3: b=b+3: c=c-3:FOR j=1 TO 3:GOSUB 6550:NEXT j:NEXT k
6530FOR k=1 TO 2:COLOR =0: a=33: b=39: c=20:FOR j=1 TO 3:GOSUB 6560:NEXT j
6540GOSUB 6550: a=a-3: b=b+3: c=c-3:FOR j=1 TO 3:GOSUB 6550:NEXT j:NEXT k:NEXT i:RETURN
6550VLIN a, b AT c: a=a+1: b=b-1: c=c-1:RETURN
6560VLIN a, b AT c: a=a+1: b=b-1: c=c+1:RETURN
6570REM                PIT
6580GR:COLOR =15: a=1: b=38: c=18:FOR i=1 TO 2:FOR j=1 TO 4:GOSUB 6890: c=c+1:NEXT j: a=a+1: b=b-1
6590FOR j=1 TO 2:GOSUB 6890: c=c+1:NEXT j: c=17:FOR j=1 TO 2:GOSUB 6890: c=c-1:NEXT j
6600 a=a+1: b=b-1: c=24:GOSUB 6890: c=15:GOSUB 6890: a=a+1: b=b-1: c=25:GOSUB 6890: c=14:GOSUB 6890: a=a+1
6610 b=b-1: c=26:GOSUB 6890: c=13:GOSUB 6890: a=a+1: b=b-1: c=27:GOSUB 6890: c=12:GOSUB 6890: a=9: b=30
6615 c=28:GOSUB 6890: c=11:GOSUB 6890: a=12: b=27: c=29:GOSUB 6890: c=10:GOSUB 6890:NEXT i
6620COLOR =0:FOR i=1 TO 2: a=1: b=13: d=26: e=38: c=10:VLIN a, e AT c: c=29:VLIN a, e AT c: c=11
6630GOSUB 6880: c=28:GOSUB 6880: b=10: d=29: c=12:GOSUB 6880: c=27:GOSUB 6880: b=8: d=31: c=13:GOSUB 6880
6640 c=26:GOSUB 6880: b=6: d=33: c=14:GOSUB 6880: c=25:GOSUB 6880: b=5: d=34: c=15:GOSUB 6880
6650 c=24:GOSUB 6880: b=4: d=35: c=16:FOR j=1 TO 2:GOSUB 6880: c=c+1:NEXT j: c=23:FOR j=1 TO 2
6660GOSUB 6880: c=c-1:GOSUB 6880: b=3: d=36: c=21:FOR j=1 TO 4:GOSUB 6880: c=c-1:NEXT j:NEXT i
6670FOR i=1 TO 2: b=14: d=25: c=11:VLIN a, e AT c: c=28:VLIN a, e AT c: c=12:GOSUB 6880: c=27:GOSUB 6880
6680 b=11: d=28: c=13:GOSUB 6880: c=26:GOSUB 6880: b=9: d=30: c=14:GOSUB 6880: c=25:GOSUB 6880
6690 b=7: d=32: c=15:GOSUB 6880: c=24:GOSUB 6880: b=6: d=33: c=16:GOSUB 6880: c=17:GOSUB 6880: c=23
6700GOSUB 6880: c=22:GOSUB 6880: b=5: d=34: c=21:FOR j=1 TO 4:GOSUB 6880: c=c-1:NEXT j:NEXT i
6710FOR i=1 TO 2: c=12:VLIN a, e AT c: c=27:VLIN a, e AT c: b=16: d=24: c=13
6720FOR j=1 TO 4:GOSUB 6880: b=b-2: d=d+2: c=c+1:NEXT j: b=16: d=24: c=26
6730FOR j=1 TO 4:GOSUB 6880: b=b-2: d=d+2: c=c-1:NEXT j
6740 b=9: d=31: c=22:GOSUB 6880: c=17:GOSUB 6880: b=8: d=32: c=18:FOR j=1 TO 4:GOSUB 6880: c=c+1:NEXT j
6750NEXT i:FOR i=1 TO 2: c=13:VLIN a, e AT c: c=26:VLIN a, e AT c: b=17: d=25: c=14:FOR j=1 TO 4:GOSUB 6880
6760 b=b-2: d=d+2: c=c+1:NEXT j: b=17: d=25: c=25:FOR j=1 TO 4:GOSUB 6880: b=b-2: d=d+2: c=c-1:NEXT j
6770 b=10: d=32: c=18:FOR j=1 TO 4:GOSUB 6880: c=c+1:NEXT j:NEXT i:FOR i=1 TO 2: c=14:VLIN a, e AT c
6780 c=25:VLIN a, e AT c: b=17: d=25: c=15:FOR j=1 TO 3:GOSUB 6880: b=b-2: d=d+2: c=c+1:NEXT j
6790 b=17: d=25: c=24:FOR j=1 TO 3:GOSUB 6880: b=b-2: d=d+2: c=c-1:NEXT j
6800 b=12: d=30: c=21:FOR j=1 TO 4:GOSUB 6880: c=c-1:NEXT j:NEXT i
6810FOR i=1 TO 2: c=15:VLIN a, e AT c: c=24:VLIN a, e AT c: b=16: d=24: c=16:FOR j=1 TO 2:GOSUB 6880
6820 b=b-2: d=d+2: c=c+1:NEXT j: b=16: d=24: c=23:FOR j=1 TO 2:GOSUB 6880: b=b-2: d=d+2: c=c-1:NEXT j
6830HLIN 18, 21 AT 13: c=29:FOR j=1 TO 3:HLIN 18, 21 AT c: c=c-1:NEXT j:NEXT i
6840FOR i=1 TO 2:VLIN 1, 38 AT 16:VLIN 1, 38 AT 23: c=14:FOR j=1 TO 3:HLIN 17, 22 AT c: c=c+1:NEXT j
6850 c=26:FOR j=1 TO 2:HLIN 17, 22 AT c: c=c-1:NEXT j:NEXT i:FOR i=1 TO 2:VLIN 1, 38 AT 17
6860VLIN 1, 38 AT 22:VLIN 1, 38 AT 18:HLIN 19, 21 AT 17:HLIN 19, 21 AT 24:NEXT i
6870VLIN 22, 38 AT 20:VLIN 1, 20 AT 20:VLIN 1, 38 AT 19:VLIN 1, 38 AT 21:RETURN
6880VLIN d, e AT c
6890VLIN a, b AT c:RETURN
6900GR:? "ZAP - SUPER BAT SNATCH! ELSEWHERESVILLE FOR YOU!"
6910FOR q=1 TO 2:COLOR =15:VLIN 12, 22 AT 18:VLIN 11, 21 AT 19:VLIN 12, 22 AT 20:FOR i=1 TO 2
7000COLOR =15: h=0: b=17: d=21: e=38: c=12:FOR j=1 TO 2:GOSUB 7120: h=h+1: e=e-1: c=c+1:NEXT j
7010COLOR =10:FOR j=1 TO 8:GOSUB 7120: h=h+2: e=e-2: c=c+1:NEXT j:NEXT i
7017 c=11:FOR k=1 TO 2:GOSUB 7020: c=10: b=17: d=21:NEXT k:GOTO 7070
7020FOR i=1 TO 2: h=10: e=28:COLOR =15:FOR j=1 TO 2:GOSUB 7120: c=c+1:NEXT j
7030COLOR =10:GOSUB 7120: c=c-2
7036 h=0: b=9: d=29: e=38:COLOR =15:FOR j=1 TO 2:GOSUB 7120
7040 c=c+1: h=h+1: e=e-1:NEXT j:COLOR =10:GOSUB 7120
7050 h=0: b=0: d=38: e=38: c=c-1:COLOR =0:FOR j=1 TO 2:GOSUB 7120: b=b+1: d=d-1: c=c+1:NEXT j
7060 b=b+1: d=d-1:FOR j=1 TO 8:GOSUB 7120: b=b+2: d=d-2: c=c+1:NEXT j:RETURN
7070 c=c+2:FOR k=1 TO 2:GOSUB 7075: c=c-1:NEXT k:GOTO 7110
7075FOR i=1 TO 2: h=10: b=17: d=21: e=28:COLOR =15:GOSUB 7120:COLOR =0: c=c-2:GOSUB 7120
7080COLOR =10: c=c+7:FOR j=1 TO 4:GOSUB 7120: h=h+2: e=e-2: c=c+1:NEXT j
7090 h=1: b=9: d=29: e=37: c=c-9:COLOR =15:FOR j=1 TO 2:GOSUB 7120: h=0: e=38: c=c-1:NEXT j
7100COLOR =0:GOSUB 7120: h=2: e=36: c=c+3:COLOR =10:FOR j=1 TO 4:GOSUB 7120: h=h+2: e=e-2: c=c+1:NEXT j
7105 c=c-3:RETURN
7110NEXT q:RETURN
7120HLIN h, b AT c:HLIN d, e AT c:RETURN
7490REM                  BUMPED WUMPUS
7500COLOR =15:VLIN 22, 33 AT 9:VLIN 25, 33 AT 8:HLIN 6, 7 AT 25:HLIN 6, 7 AT 26
7510HLIN 6, 7 AT 32:HLIN 6, 7 AT 33:VLIN 34, 36 AT 6:PLOT 7, 36:COLOR =10:VLIN 34, 35 AT 9
7520COLOR =15:HLIN 9, 11 AT 36:HLIN 9, 11 AT 37:COLOR =15:VLIN 35, 38 AT 12:FOR i=1 TO 100:NEXT i
7530VLIN 22, 33 AT 8:VLIN 25, 33 AT 7:COLOR =10:VLIN 34, 37 AT 8:COLOR =15:VLIN 35, 38 AT 11
7540COLOR =0:VLIN 22, 35 AT 9:VLIN 35, 38 AT 12:FOR i=1 TO 100:NEXT i:COLOR =15:VLIN 22, 25 AT 7
7550VLIN 25, 33 AT 6:COLOR =10:VLIN 34, 35 AT 7:PLOT 7, 37:COLOR =15:VLIN 35, 38 AT 9:COLOR =0:VLIN 22, 35 AT 8
7560VLIN 35, 38 AT 11:VLIN 36, 37 AT 10:FOR i=1 TO 100:NEXT i:COLOR =15:VLIN 22, 25 AT 6:VLIN 35, 37 AT 8
7570COLOR =0:VLIN 22, 35 AT 7:PLOT 7, 37:VLIN 35, 38 AT 10:VLIN 35, 38 AT 9:FOR i=1 TO 100:NEXT
7580VLIN 35, 38 AT 8:VLIN 35, 38 AT 7:VLIN 22, 38 AT 6:RETURN
7590REM                  WUMPUS GETS YOU
7600GR:COLOR =15: xa=17: xd=21: ya=10:FOR j=1 TO 2:GOSUB 7940: xa=xa-2: xd=xd+2:NEXT j
7610GOSUB 7940: xa=xa-1: xd=xd+1:FOR j=1 TO 4:GOSUB 7940:NEXT j: xa=xa-1: xd=xd+1:FOR j=1 TO 8
7620GOSUB 7940:NEXT j: xa=xa+1: xd=xd-1:FOR j=1 TO 4:GOSUB 7940:NEXT j
7630 xa=xa+1: xd=xd-1:FOR j=1 TO 2:GOSUB 7940: xa=xa+2: xd=xd-2:NEXT j:GOSUB 7940
7640COLOR =12: ea=14: eb=16: ec=22: ed=24: za=17:FOR j=1 TO 3:HLIN ea, eb AT za:HLIN ec, ed AT za
7650 za=za+1:NEXT j: za=za-1:COLOR =0:PLOT 15, 19:PLOT 23, 19:COLOR =3:HLIN 15, 23 AT 24
7660VLIN 24, 26 AT 24:HLIN 23, 15 AT 26:VLIN 26, 24 AT 14
7670REM                ENLARGE HEAD AND EYES
7680COLOR =15:GOSUB 7720:COLOR =15: ya=8:GOSUB 7940: zb=zb+1:GOSUB 7810:FOR l=1 TO 3:COLOR =15
7690 ya=ya-17:GOSUB 7940: zb=zb+1: ay=1:GOSUB 7810:NEXT l: ya=26: yc=27:FOR i=1 TO 7: xa=11: xb=11: xc=27
7700 xd=27:COLOR =15:GOSUB 7900: ya=ya-6:NEXT i:GR:RETURN
7710REM                ENLARGE HEAD
7720 xb=18: xc=20: ya=9:GOSUB 7940:GOTO 7730
7730FOR j=1 TO 2: xa=xa-2: xb=xb-2: xc=xc+2: xd=xd+2:GOSUB 7950:NEXT j
7740 xa=xa-1: xb=xb-2: xc=xc+2: xd=xd+1:GOSUB 7950: xa=xa-1: xb=xb-1: xc=xc+1: xd=xd+1:FOR j=1 TO 4
7750GOSUB 7950:NEXT j: xa=xa-1: xb=xb-1: xc=xc+1: xd=xd+1:FOR j=1 TO 8:GOSUB 7950:NEXT j
7760 xa=xa+1: xb=xb+1: xc=xc-1: xd=xd-1
7770FOR j=1 TO 4:GOSUB 7950:NEXT j: xa=xa+1: xb=xb+1: xc=xc-1: xd=xd-1:GOSUB 7950
7780 xa=xa+1: xb=xb+2: xc=xc-2: xd=xd-1:FOR j=1 TO 2:GOSUB 7950: xa=xa+2: xb=xb+2: xc=xc-2: xd=xd-2:NEXT j
7790HLIN xa, xd AT ya: zb=3:GOTO 7860
7800REM                ENLARGE TOP OF HEAD
7810FOR j=1 TO 2: xa=xa-2: xb=xb-2: xc=xc+2: xd=xd+2:GOSUB 7950:NEXT j
7820 xa=xa-1: xb=xb-2: xc=xc+2: xd=xd+1:GOSUB 7950: xa=xa-1: xb=xb-1: xc=xc+1: xd=xd+1:FOR j=1 TO 4
7830GOSUB 7950:NEXT j: xa=xa-1: xb=xb-1: xc=xc+1: xd=xd+1:FOR j=1 TO 8:GOSUB 7950:NEXT j
7840 xa=17: xb=18: xc=20: xd=21:IF ay=1 THEN RETURN
7850REM                ENLARGE EYES
7860COLOR =12: ea=ea-1: eb=eb+1: ec=ec-1: ed=ed+1:FOR j=1 TO zb:PLOT ea, za
7870 za=za-1:NEXT j:HLIN ea, eb AT za:FOR j=1 TO zb: za=za+1:PLOT eb, za:NEXT j
7880FOR j=1 TO zb:PLOT ed, za
7890 za=za-1:NEXT j:HLIN ed, ec AT za:FOR j=1 TO zb: za=za+1:PLOT ec, za:NEXT j:RETURN
7900FOR j=1 TO 4:GOSUB 7950:NEXT j: xa=xa+1: xb=xb+1: xc=xc-1: xd=xd-1:GOSUB 7950
7910 xa=xa+1: xb=xb+2: xc=xc-2: xd=xd-1:FOR j=1 TO 2:GOSUB 7950: xa=xa+2: xb=xb+2: xc=xc-2: xd=xd-2:NEXT j
7920HLIN xa, xd AT ya:COLOR =3:HLIN 14, 24 AT yc: yc=yc-1:COLOR =15
7930HLIN 15, 23 AT yc: yc=yc-1:COLOR =0:HLIN 15, 23 AT yc: yc=yc+3:RETURN
7940HLIN xa, xd AT ya: ya=ya+1:RETURN
7950HLIN xb, xa AT ya:HLIN xc, xd AT ya: ya=ya+1:RETURN
