10REM THE CELTIC TAROT
20GOSUB 380
30GOSUB 250
40GOSUB 530
50? r$; "?":?
60? TAB(8); "...LET ME SEE..."
70GOSUB 530:GOSUB 530
80REM ******
90REM PREDICT
100FOR j=1 TO 10
110GOSUB 510:REM DELAY
120? "******************************"
130? a$(j)
140GOSUB 530
150 x=INT(RND(1)*22):IF h(x)=1 THEN 150
160 h(x)=1
170? TAB(6); "------------"
180? b$(x)
190? "******************************"
200GOSUB 530
210NEXT j
220GOSUB 510
230END
240REM *******
250REM ENTER QUESTION
260GOSUB 510
270? "Enter question or concern now."
280? "I will use the Celtic Cross..."
290REM t "t will use the Celtic Cross..."
300GOSUB 510
310INPUT r$
320GOSUB 510
330? TAB(4); "Please Stand By...."
340GOSUB 530
350HOME
360RETURN
370REM **********
380REM INIT
390HOME
400? "--->PRESS ANY KEY<---"
403 h=PEEK(64885)
404 pu=RND(2):IF PEEK(64885)=h THEN 404
410DIM a$(10), b$(21), h(21)
420FOR j=1 TO 10
430READ a$(j)
440NEXT j
450FOR j=0 TO 21
460 h(j)=0
470READ b$(j)
480NEXT j
490RETURN
500REM **************
510REM DELAY
520?:?
530FOR z=1 TO 2000:NEXT
540RETURN
550REM **************
560REM INTRO DATA
570DATA "THIS CARD IS WHERE YOU STAND   NOW..."
580DATA "THIS CARD IS FOR THE NEAR      FUTURE..."
590DATA "AND THIS ONE IS WHAT YOU MIGHT DO"
600DATA "THIS IS SOMETHING IN THE PAST, RELEVANT TO YOUR   QUESTION..."
610DATA "THIS CARD RELATES TO A MORE    RECENT PAST EVENT"
620DATA "NOW, THIS CARD INDICATES YOUR  POSITION IN SIX MONTHS OR SO.."
630DATA "IN YOUR LIFE OR WORK, THIS MOSTCLOSELY INFLUENCES YOU..." 
640DATA "THIS CARD REPRESENTS SOCIAL    INFLUENCES ON YOUR QUERY..."
650DATA "YOUR HOPES AND FEARS ARE       REFLECTED IN THIS CARD..."
660DATA "AND, FROM THESE, IN REPLY, THISCARD POINTS TOWARD AN ANSWER..."
670REM ******
680REM card data
690DATA "THE FOOL: NEW BEGINNINGS AND   CHALLENGES"
700DATA "THE MAGICIAN: OUTWARD PROGRESS,DECISIONS TO BE MADE..."
710DATA "THE HIGH PRIESTESS: WISDOM, A  PROBLEM WILL BE SIMPLIFIED..."
720DATA "THE EMPRESS: A STABLE SITUATIONAND GOOD FORTUNE..."
730DATA "THE EMPEROR: GOALS WILL BE     REACHEDM BEWARE OF RUTHLESSNESS"
740DATA "THE HIGH PRIEST: LISTEN TO     ADVICE, UNDERSTANDING LIKELY..."
750DATA "THE LOVERS: A POSITIVE DECISIONLIKELY, RELATIONSHIPS PROSPER.."
760DATA "THE CHARIOT: A GOOD STAGE IN   YOUR LIFE ATTAINED, TRAVEL     LIKELY..."
770DATA "JUSTICE: BALANCE WILL BE       REACHED, DUE REWARD LIKELY..."
780DATA "THE HERMIT: RE-EVALUATION OF   PRIORITIES INDICATED, INNER    GROWTH"
790DATA "WHEEL OF FORTUNE: GROWTH, LUCK,DECISIONS TO BE MADE..."
800DATA "STRENGTH: YOUR INNER QUALITIES WILL INSURE YOU MEET THE TEST"
810DATA "HANGED MAN:CAST AWAY MATERIAL  VALUES, SACRIFICE REWARDED..."
820DATA "DEATH: FRESH AWARENESS WILL    COME FROM TEMPORARY SETBACKS.."
830DATA "ANGEL OF TIME (TEMPERANCE):    MODERATION DEMANDED;WISE CHOICESEEN..."
840DATA "THE DEVIL: BE WARY OF GIVING INTOO EASILY TO YOUR WHIMS...."
850DATA "THE TOWER: UNFORTUNATE INDICA- TIONS, REGROWTH CAN BE EXPECTED"
860DATA "THE STAR:VERY POSITIVE, FRESH  DEVELOPMENTS SEEN..."
870DATA "THE MOON: TRUST YOUR HEART, NOTYOUR HEAD..."
880DATA "THE SUN: A GOAL WITHIN REACH,  LIGHT AFTER DARKNESS..."
890DATA "JUDGEMENT: A PERIOD OF FRESH   BEGINNINGS AND ASSESSING VALUES"
900DATA "THE WORLD: COMPLETION OF A     DIFFICULT TASK, ATTAINMENT OF AGOAL..."
