90 l=1
100DIM rm$(37), dir(37, 6), o$(37), o(37), ve$(20), t$(12)
110 l=1: ap=0: ca=0: ha=0: pd=0: k=0:FOR x=1 TO 37:READ rm$(x)
120FOR y=1 TO 6:READ dir(x, y):NEXT y
130NEXT x
140FOR x=1 TO 37:READ o$(x):NEXT
145FOR x=1 TO 37:READ o(x):NEXT
150FOR x=1 TO 20:READ ve$(x):NEXT
155FOR x=1 TO 12:READ t$(x):NEXT
200HOME:? "I am "; rm$(l)
210 s=0:?:? "Other things I see: "
212IF li=0 AND (l=21 OR l=22 OR l=24 OR l=30) THEN ? "It's too dark to see.":GOTO 300
213IF li=0 AND (l=32 OR l=29 OR l=15 OR l=16 OR l=17 OR l=19) THEN ? "It's too dark to see.":GOTO 300
214IF li=0 AND l>34 THEN ? "It's too dark to see.":GOTO 300
215IF o(13)<>-1 AND (l=32 OR l=29 OR l=15 OR l=16 OR l=17 OR l=19 OR l>34) THEN ? "It's too dark to see.":GOTO 300
216IF o(13)<>-1 AND (l=21 OR l=22 OR l=24 OR l=30) THEN ? "It's too dark to see.":GOTO 300
218FOR x=1 TO 37
220IF o(x)=l THEN ? "  "; o$(x): s=1
230NEXT
235IF s=0 THEN ? "  Nothing interesting"
300?:? "Obvious exits:"
310FOR x=1 TO 6
320IF dir(l, 1)<>0 THEN ? "  north"; 
321IF dir(l, 2)<>0 THEN ? "  south"; 
322IF dir(l, 3)<>0 THEN ? "  east"; 
323IF dir(l, 4)<>0 THEN ? "  west"; 
324IF dir(l, 5)<>0 THEN ? "  up"; 
325IF dir(l, 6)<>0 THEN ? "  down"
400?:? "==============================="
405IF br=1 AND pl=1 THEN GOTO 9200
410INPUT "What should I do? "; a$
412IF LEFT$(a$, 3)="inv" THEN GOTO 450
413IF LEFT$(a$, 3)="loo" THEN HOME:GOTO 200
414IF LEFT$(a$, 3)="qui" THEN 9110
415IF LEFT$(a$, 3)="lis" THEN 3650
420IF LEN(a$)<>1 THEN 500
425IF l=4 AND a$="n" THEN GOSUB 8990:GOTO 200
430IF a$="n" AND dir(l, 1)<>0 THEN  l=dir(l, 1):GOTO 200
432IF a$="s" AND dir(l, 2)<>0 THEN  l=dir(l, 2):GOTO 200
433IF a$="e" AND dir(l, 3)<>0 THEN  l=dir(l, 3):GOTO 200
434IF a$="w" AND dir(l, 4)<>0 THEN  l=dir(l, 4):GOTO 200
435IF a$="u" AND dir(l, 5)<>0 THEN  l=dir(l, 5):GOTO 200
436IF a$="d" AND dir(l, 6)<>0 THEN  l=dir(l, 6):GOTO 200
440? CHR$(7); :? "I can't go that way!":GOTO 400
450 c=0:?:? "I am carrying:"
455FOR x=1 TO 37:IF o(x)=-1 THEN ? " "; o$(x): c=1
460NEXT:IF c=0 THEN ? " nothing"
470GOTO 400
500 p=0:FOR x=1 TO LEN(a$):IF MID$(a$, x, 1)=CHR$(32) THEN  p=x
510NEXT
515IF LEFT$(a$, 2)="go" THEN  v=15:GOTO 550
516IF LEFT$(a$, 3)="tak" THEN  v=1:GOTO 550
517IF LEFT$(a$, 3)="ord" THEN ? "I don't see the waiter.":GOTO 400
518IF LEFT$(a$, 3)="che" THEN  v=2:GOTO 550
519IF LEFT$(a$, 3)="des" THEN  v=19:GOTO 550
520IF p<4 THEN ? " I don't understand.":GOTO 400
530 v=0:FOR x=1 TO 20:IF LEFT$(a$, 3)=LEFT$(ve$(x), 3) THEN  v=x
540NEXT
541IF LEFT$(a$, 3)="lif" THEN  v=5
545IF v=0 THEN ? "I don't know how to "; a$:GOTO 400
550 ob=0:FOR x=1 TO 37:IF MID$(a$, p+1, 4)=LEFT$(o$(x), 4) THEN  ob=x
555NEXT
560IF MID$(a$, p+1, 3)="dru" THEN  ob=15
561IF MID$(a$, p+1, 3)="car" THEN  ob=21
563IF MID$(a$, p+1, 3)="doo" AND l=4 THEN  ob=23
564IF MID$(a$, p+1, 3)="pap" THEN  ob=18
565IF MID$(a$, p+1, 3)="cor" THEN  ob=19
566IF MID$(a$, p+1, 3)="boa" AND l=7 THEN  ob=10
567IF MID$(a$, p+1, 3)="boa" AND l=15 THEN  ob=7
568IF MID$(a$, p+1, 3)="ele" THEN  ob=26
569IF MID$(a$, p+1, 3)="bil" THEN  ob=11
570IF MID$(a$, p+1, 3)="pre" THEN  ob=5
571IF MID$(a$, p+1, 3)="che" THEN  ob=17
578IF ob=0 AND LEN(a$)<=p THEN ? "I don't understand.":GOTO 400
580IF ob=0 THEN  le=LEN(a$):? "I don't know what a "; RIGHT$(a$, le-p); " is.":GOTO 400
590ON v GOTO 600, 700, 800, 900, 2000, 2050, 3000, 3050, 3100, 3150, 3200, 3250, 3300, 3350, 3400, 3450, 3500, 3550, 3600, 3700
600IF o(ob)=-1 THEN ? "I already have it.":GOTO 400
601IF ob=29 AND (l=1 OR l=30) THEN ? "I can't get that.":GOTO 400
602IF ob=33 THEN ? "Ouch! He hit me!": b=1:GOSUB 9000:? "I don't think he liked that!":GOSUB 9000: l=1: b=1.5:GOTO 200
605IF ca+1>5 THEN ? "I can't carry any more.":GOTO 400
610IF o(ob)<>l THEN ? "I don't see it here.":GOTO 400
620IF ob=2 OR ob=3 OR ob=5 OR ob=6 OR ob=10 OR ob=23 THEN ? "I can't get "; RIGHT$(a$, p+1):GOTO 400
621IF ob=7 THEN ? "I can't, one corner is fastened down.":GOTO 400
622IF ob=25 OR ob=26 OR ob=31 OR ob=32 OR ob=35 OR ob=36 THEN ? "I can't get that.":GOTO 400
625IF ob=15 THEN ? "I can't get him.":GOTO 400
630IF l=25 AND ob=4 AND o(17)=0 THEN ? "  OK": ca=ca+1: o(ob)=-1: o(17)=25:GOTO 400
632IF ob=16 THEN  o$(16)="apron"
634IF (ob=28 AND pd=0) OR ob=34 THEN ? "I can't. It's attached to      something":GOTO 400
690? "  OK": ca=ca+1: o(ob)=-1
695GOTO 400
700IF o(ob)<>-1 THEN ? "I don't have it.":GOTO 400
710IF ob=8 AND l=34 THEN ? "The girl takes the hat and     hands me a claim ticket.": o(8)=0: o(17)=-1:GOTO 400
720IF ob=16 THEN  o$(16)="apron"
750? "  OK": ca=ca-1: o(ob)=l:GOTO 400
800IF ob=29 AND l=30 THEN ? "It says: OUT OF ORDER":GOTO 400
801IF ob=10 AND l=7 AND (o(12)=0 OR o(12)=7) THEN ? "I see a recipe.": o(12)=7:GOTO 400
802IF ob=29 AND l=1 THEN ? "It says:":? "      The DOCKSIDE":GOTO 400
803IF o(ob)<>l AND o(ob)<>-1 THEN ? " I don't see it here.":GOTO 400
805IF o(ob)<>-1 THEN ? "I don't have it.":GOTO 400
810IF ob=18 THEN ? "It says: ":? "   18-22-11":GOTO 400
815IF ob=17 THEN ? "It says: ":? "   112":GOTO 400
835IF ob=22 THEN ? " It says: ":? "    Today's special ":? "     Linguini with clam sauce.":GOTO 400
845IF ob=25 AND (l=4 OR l=8) THEN ? "It says: PRIVATE":GOTO 400
847IF ob=21 THEN ? " It says:":?:?:GOTO 9250
850IF ob=11 THEN ? "It says: LOWE'S LIQUORS and is made out to Enrico Cappucino":GOTO 400
860IF ob=12 THEN ? "Now is not the time to collect recipes.":GOTO 400
890? " I can't read "; o$(ob):GOTO 400
900IF ob=7 AND l=15 THEN ? "A board looks loose.": o(7)=15:GOTO 400
902IF ob=35 AND (l=14 OR l=18 OR l=32) THEN 910
903IF ob=33 AND l=7 THEN ? "He's a big burly redhead with a 'MOM' tattoo on his left arm.":GOTO 400
905IF o(ob)<>-1 AND o(ob)<>l THEN ? "I don't see it here.":GOTO 400
910IF ob=4 THEN ? " It's a red carnation. Pretty!"
912IF ob=4 AND o(17)=0 AND l=25 THEN ? "Hmmm....it looks like there is something under it."
914IF ob=4 GOTO 400
920IF ob=10 THEN ? "I see a recipe": o(12)=7:GOTO 400
925IF ob=12 THEN ? "It's a recipe for linguini withclam sauce.":GOTO 400
930IF ob=2 AND li<>1 THEN ? "It's too dark to see.":GOTO 400
940IF ob=2 AND li=1 THEN ? "The trashcans are full,maybe I should search them.":GOTO 400
942IF ob=3 THEN ? "A sign says Hat Check. The     pretty girl behind the counter smiles at me.":GOTO 400
945IF ob=23 AND l=4 THEN ? "It's closed.":GOTO 400
950IF ob=8 THEN ? "It's a gray felt with a dark   hatband.A tag inside says:     '71/4'.The sweatband is stained"
951IF ob=8 AND o(18)=0 THEN ?:? "Aha!! I found something.": ca=ca+1:? "I've got it!"
952IF ob=8 AND o(18)=0 THEN ? "A folded piece of paper was    inside the sweatband": o(18)=-1:GOTO 400
955IF ob=18 OR ob=17 THEN ? "There's writing on it.":GOTO 400
957IF ob=26 THEN ? "There's a sign on it.": o(27)=30:GOTO 400
960IF ob=19 THEN ? "It's a rectangular package     wrapped in brown paper, tied   with heavy cord."
961IF ob=19 AND o(19)=-1 THEN ? "Strange, for a small package,  it's very heavy."
962IF ob=19 GOTO 400
964IF ob=6 THEN ? "It's a large black safe with a combination lock.":GOTO 400
966IF ob=9 THEN ? "It looks very sharp.":GOTO 400
968IF ob=16 THEN ? "It's green like the bartender's":GOTO 400
970IF ob=7 THEN ? "One of the floor boards is loose.": o(7)=15:GOTO 400
972IF (ob=35 AND l=14 AND dir(14, 4)=0) OR (ob=35 AND l=27 AND dir(27, 4)=0) THEN ? "The door is closed.":GOTO 400
973IF ob=35 AND (l=14 OR l=27) THEN ? "The door is open.":GOTO 400
974IF ob=35 AND l=32 AND o(13)=-1 THEN ? "It's a heavy looking door with a smaller door-like a peephole-in it.":GOTO 400
975IF (ob=35 AND l=28 AND dir(24, 4)=0) THEN ? "The door is closed.":GOTO 400
976IF ob=35 AND l=28 THEN ? "The door is open.":GOTO 400
978IF ob=11 THEN ? "It looks like a liquor bill": o$(11)="liquor bill":GOTO 400
990? " I see nothing interesting.":GOTO 400
1000DATA  on a street in front of a building. There's a strange    mixture of smells in the air..... food and river smells. 
1010DATA  4,0,2,0,0,0  
1020DATA   on a street before a long dark alley. 
1030DATA  22,0,3,1,0,0 
1040DATA   on a street in front of a rundown warehouse. It looks    deserted. 
1050DATA  0,0,0,2,0,0     
1060DATA  in a small lobby with     faded pictures of Venice on    the wall.
1065DATA  6,1,0,0,0,0
1070DATA  in a small office.
1075DATA  8,0,0,4,0,0 
1080DATA  in a crowded dimly lit    dining room. 
1085DATA  7,4,9,0,0,0 
1090DATA   "in a hot,noisy kitchen.   There is a strong garlic smell.A burly cook is busy at the    stove." 
1095DATA  11,6,26,0,0,0 
1100DATA  in a crowded smoke-filled room.Music is playing and      everyone seems to be having a  good time. 
1105DATA  32,0,0,31,10,0
1110DATA  in a small restroom.That'sstrange..I think I hear music  faintly through the wall.   
1115DATA  0,0,0,6,0,0 
1120DATA   "on a steep narrow         staircase"
1125DATA  0,0,0,0,13,8
1130DATA  on a quiet backstreet.    Light from a screen door       partially illuminates the area. 
1135DATA  20,0,32,0,0,0 
1140DATA  along the bank of a river. 
1145DATA  0,32,0,0,0,0  
1150DATA  at the top of a flight of stairs. A long narrow hallway  runs north from here.
1155DATA  14,0,0,0,0,10 
1160DATA  near the end of a narrow  hallway. There is a door to thewest.
1165DATA  27,13,0,0,0,0
1170DATA  in a small room.The floor creaks as I walk across it.The room appears to be empty.
1175DATA  0,0,14,0,0,0
1180DATA  in a small room lined withshelves.
1185DATA  0,0,27,0,0,0 
1190DATA  in a storeroom lined with shelves.
1195DATA  0,0,28,0,0,0
1200DATA  on a window ledge. I hear snoring noises!
1205DATA  0,0,0,27,0,0 
1206DATA  on a catwalk above an     alley. 
1207DATA  0,0,29,18,0,0
1210DATA  on an old wooden dock.  
1215DATA  0,11,0,0,0,0 
1220DATA  on a street near the end  of a small alley.
1225DATA  12,22,24,32,0,0
1230DATA  "in a long, dark alley."  
1235DATA  21,2,0,0,0,0 
1240DATA  among piles of old crates.  
1245DATA  23,35,37,23,0,0
1250DATA  on a road filled with     potholes behind an apparently  abandoned warehouse. 
1255DATA   0,30,0,21,0,0 
1260DATA  sitting at a small table  covered with a red and white   checked tablecloth. 
1265DATA  0,0,0,0,6,0
1270DATA  in a small pantry.  
1275DATA  0,0,0,7,0,0  
1280DATA  near the middle of a      narrow hallway.
1285DATA  28,14,0,0,0,0
1290DATA  at the north end of a darknarrow hallway. There is a     door to the west.
1295DATA  0,27,0,0,0,0
1300DATA  in a large room.Looks likea warehouse loft.
1310DATA  0,0,0,19,0,0
1320DATA  "in a cavernous,dusty old  warehouse. It appears deserted,although there are some old    crates lying around."
1325DATA  24,35,0,0,0,0  
1330DATA  sitting at a bar. The     bartender places a drink in    front of me. 
1335DATA  0,0,0,0,8,0 
1340DATA  on a dark street.    
1345DATA  12,0,21,11,0,0   
1350DATA  among piles of old crates. I'm at a dead end.  
1360DATA  0,37,0,0,0,0  
1365DATA  at a counter. A sign says Hat Check. A pretty girl is    smiling at me. 
1370DATA  0,0,4,0,0,0
1372DATA  among piles of old crates. 
1374DATA  35,35,35,36,0,0
1376DATA  among piles of old crates. 
1378DATA  30,23,36,35,0,0
1380DATA  among piles of old crates.
1382DATA  33,35,37,37,0,0 
1400DATA  crowbar,trashcans,counter,flower ,printing press,safe,floor board (loose),hat,knife,bulletin board 
1420DATA  bill,recipe,lantern,matches,drunk,apron,claim check 
1440DATA  folded piece of paper,package,key,small business card,menu,"door with sign: PRIVATE"  
1445DATA  door, "door with sign: PRIVATE",freight elevator,sign,padlock,sign,plates (counterfeit) 
1447DATA  table,button,cook,rope,door,window (boarded),hammer  
1500DATA  33,22,4,25,29,5,0,0,7,7,20,0,26
1510DATA   25,22,31,0,0,0,17,0,0,4,32,8,30,0,28,1,0,6,0,0,18,27,27,16
1600DATA  get,drop,read,exam,move,frisk,light,open,pull   
1610DATA   knock,search,unlock,push,give,go,wear,remove,cut,break,stab 
1650DATA   "Well, OK","..let's see.","...an old shoe..","....ah..some empty clam shells.." 
1655DATA  "...Yuk!...","..a broken glass..","...hmmmm......","..I don't know what this is.","...but it is GROSS.."
1660DATA  ".....PHEW!!!....","..a rotten fish...","nothing valuable or interesting in here!"  
2000IF o(ob)<>l AND o(ob)<>-1 THEN ? "I don't see it here.":GOTO 400
2010IF ob=4 AND l=25 AND o(17)=0 THEN ? "OK!": o(17)=25:? "I found something.":GOTO 400
2015IF ob=7 AND o(32)=0 THEN ? "OK": b=1:GOSUB 9000:? "I found something!": o(32)=15:GOTO 400
2046IF ob=2 OR ob=5 OR ob=6 THEN ? "It's too heavy."
2047IF ob=3 OR ob=10 OR ob=26 OR ob=32 THEN ? "I can't move that.":GOTO 400
2048? "OK":GOTO 400
2050IF ob=15 AND l<>22 THEN ? " I don't see him here.":GOTO 400
2052IF ob=15 AND l=22 AND li<>1 THEN ? " I can't see him..it's too dark.":GOTO 400
2055IF ob=15 AND l=22 AND li=1 THEN ? " OK":FOR x=1 TO 2000:NEXT:? " I found something!!": o(21)=22:GOTO 400
2060? " I can't frisk "; RIGHT$(a$, p+1):GOTO 400
3000IF o(ob)<>-1 AND o(ob)<>l THEN ? "I don't see it here.":GOTO 400
3010IF ob<>13 AND ob<>14 THEN ? " I can't light that.":GOTO 400
3015IF ob=14 AND o(14)<>-1 THEN ? " I don't have any matches.":GOTO 400
3020IF ob=14 THEN ? " The match flares up....":? "..and goes out.":GOTO 400
3030IF ob=13 AND o(13)<>-1 THEN ? " I don't have it.":GOTO 400
3035IF ob=13 AND o(14)<>-1 THEN ? " I need something to light it  with.":GOTO 400
3040? " The lantern is lit.": li=1:GOTO 400
3050IF ob=35 AND l<>4 AND l<>8 AND l<>14 AND l<>27 AND l<>28 AND l<>32 THEN ? "I don't see it here.":GOTO 400
3052IF ob<>35 AND o(ob)<>-1 AND o(ob)<>l THEN ? "I don't see it here.":GOTO 400
3055IF ob=23 AND l=4 THEN GOSUB 8900: l=1:GOTO 200
3060IF ob=35 AND l=8 AND ap=0 THEN GOSUB 8900: l=1:GOTO 200
3065IF ob=35 AND l=8 THEN  l=5:GOTO 200
3066IF ob=28 THEN ? "It's locked.":GOTO 400
3070IF ob=6 THEN INPUT "Enter the combination "; a$:GOSUB 8950:GOTO 400
3072IF ob=19 THEN ? "I can't. The cords are too     tight.":GOTO 400
3074IF ob=35 AND l=28 AND pd=0 THEN ? "I can't.There's a padlock      on it.":GOTO 400
3076IF ob=35 AND l=28 THEN ? "OK,the door is now open.": dir(28, 4)=17:GOTO 400
3078IF ob=35 AND l=14 AND k=0 THEN ? "I can't, it's locked.":GOTO 400
3080IF ob=35 AND l=14 THEN ? "The door is now open.": dir(14, 4)=15:GOTO 400
3082IF ob=35 AND l=32 THEN ? "I can't.The door is bolted fromthe inside.":GOTO 400
3084IF ob=35 AND l=27 THEN ? "OK": dir(27, 4)=16:GOTO 400
3100IF o(ob)<>l AND o(ob)<>-1 THEN ? "I don't see it here.":GOTO 400
3110IF ob=34 THEN ? "OK I hear a creaking noise.":GOSUB 9000:? "A catwalk now spans the alley.": dir(18, 3)=19:GOTO 400
3115IF ob=36 THEN GOTO 8600
3140? "OK, nothing happened.":GOTO 400
3150IF l<>32 THEN 3160
3155IF ob=35 AND o(13)=-1 AND li=1 THEN GOTO 8930
3157IF ob=35 AND (o(13)<>-1 OR li=0) THEN ? "What door?":GOTO 400
3160? "Knocking didn't do any good.":GOTO 400
3200GOTO 3210
3210IF ob=2 AND li<>1 AND o(13)<>-1 THEN ? "It's too dark":GOTO 400
3215IF ob=2 THEN HOME:FOR x=1 TO 12:? t$(x): b=.75:GOSUB 9000:NEXT:GOSUB 9000:GOTO 9100
3220? "I found nothing of interest.":GOTO 400
3250IF l=14 AND o(20)<>-1 THEN ? "I don't have the key.":GOTO 400
3252IF l=14 AND ob=35 THEN ? "OK, the door is now unlocked.": k=1:GOTO 400
3254IF l=5 AND ob=6 THEN GOTO 3070
3258? "I can't unlock that.":GOTO 400
3300IF o(ob)<>l THEN ? "I don't see it here.":GOTO 400
3310IF ob=32 THEN ? "OK, I hear a faint grinding    noise."
3315IF wi=0 THEN  wi=1: o$(36)="window,open (a boarded panel has slid aside)": dir(27, 3)=18:GOTO 400
3316IF wi=1 THEN  wi=0: o$(36)="window (boarded)": dir(27, 3)=0:GOTO 400
3320IF ob=36 THEN GOTO 8600
3348? "OK, but nothing happens.":GOTO 400
3350IF o(ob)<>-1 THEN ? "I don't have it.":GOTO 400
3355IF l=34 AND ob=17 AND o(8)=0 THEN GOSUB 8920:GOTO 400
3357IF ob=8 THEN GOTO 710
3360IF l=34 AND ob=4 THEN ? "The girl smiles and says:":? "    Thank you": ca=ca-1: o(4)=0:GOTO 400
3390? "OK": o(ob)=l: ca=ca-1:GOTO 400
3400IF ob=35 AND l=11 THEN GOTO 9260
3410IF ob=3 THEN  l=34:GOTO 200
3420IF ob=31 THEN  l=25:GOTO 200
3430IF ob=35 AND (l=32 OR l=4 OR l=8) THEN ? "The door is closed.":GOTO 400
3435IF ob=35 AND (l=14 AND dir(14, 4)=0) OR ob=35 AND (l=27 AND dir(27, 4)=0) THEN ? "The door is closed.":GOTO 400
3437IF ob=35 AND (l=28 AND dir(28, 4)=0) THEN ? "The door is closed.":GOTO 400
3438IF ob=35 AND l=14 THEN  l=15:GOTO 200
3439IF ob=35 AND l=27 THEN  l=16:GOTO 200
3440IF ob=35 AND l=28 THEN  l=17:GOTO 200
3448? "I can't go there.":GOTO 400
3450IF o(ob)<>-1 THEN ? "I don't have it.":GOTO 400
3460IF ob=8 THEN ? "OK, but it's a little small."
3465IF ob=8 AND o(18)=0 THEN ? "Something is scratching me.":GOTO 400
3468IF ob=8 THEN GOTO 400
3470IF ob=4 THEN ? "OK. I look natty..ready for a  night on the town.":GOTO 400
3475IF ob=16 THEN ? "OK": o$(16)="apron-I'm wearing it": ap=1:GOTO 400
3490? "I can't wear that.":GOTO 400
3500IF o(ob)<>-1 THEN ? "I don't have it.":GOTO 400
3510IF ob=8 AND ha=1 THEN ? "  OK": ha=0:GOTO 400
3520IF ob=16 AND ap=1 THEN ? "  OK": ap=0:GOTO 400
3548? "I'M NOT WEARING IT.":GOTO 400
3550IF o(ob)<>-1 THEN ? "I don't have it.":GOTO 400
3555IF ob=19 AND o(9)<>-1 THEN ? "I don't have anything to cut   with.":GOTO 400
3560IF ob=19 THEN ? "I've found the plates!": o$(19)="package,empty": o(30)=-1: o(19)=l:GOTO 400
3590? "I can't cut that.":GOTO 400
3600IF o(ob)<>l AND o(ob)<>-1 THEN ? "I don't see it here.":GOTO 400
3605IF ob=28 AND pd=1 THEN ? "It's already broken.":GOTO 400
3607IF ob=28 AND o(1)<>-1 THEN ? "I don't have anything to break it with.":GOTO 400
3610IF ob=28 THEN ? "There's a loud snap and the    padlock falls to the floor.": pd=1: o$(28)="padlock,broken":GOTO 400
3620IF ob=5 AND o(1)=-1 THEN ? "OK!!": o$(5)="broken printing press": br=1:GOTO 400
3625IF ob=30 AND o(37)=-1 THEN ? "OK!!": o$(30)="plates, destroyed": pl=1:GOTO 400
3630IF ob=5 OR ob=30 THEN ? "I don't have anything to break it with.":GOTO 400
3640? "I can't break that.":GOTO 400
3649REM       listen
3650IF l=8 OR l=31 THEN ? "I hear music.":GOTO 400
3655IF l=7 THEN ? "I hear the usual kitchen noises":GOTO 400
3660IF l=9 THEN ? "I hear music if I listen       closely":GOTO 400
3665IF l=22 OR l=19 THEN ? "I hear snoring.":GOTO 400
3690? "I hear nothing interesting.":GOTO 400
3700IF ob=33 AND l<>7 THEN ? "I don't see him here.":GOTO 400
3710IF ob=33 AND o(9)<>-1 THEN ? "I don't have a knife.":GOTO 400
3720IF ob=33 THEN ? "Oh no. He did NOT like that.":GOSUB 9000:GOTO 8500
3740? "That doesn't seem like a practical idea.":GOTO 400
8100? "The girl takes the hatand hands me a claim ticket.": o(8)=0: o(17)=-1:GOTO 400
8500? "He grabs the knife.": b=.75:GOSUB 9000:? "He throws the knife.":GOSUB 9000
8510? "Now he is breaking my neck.":GOSUB 9000:GOTO 9110
8600? "It won't budge.": b=1:GOSUB 9000:? "Uh,oh!":GOSUB 9000:? "An alarm has gone off!!"
8610GOSUB 9000:? "I hear heavy footsteps!":GOSUB 9000:? "I've been shot!":GOTO 9110
8900? "A giant redhead suddenly":? "appears, grabs me by the back  of the neck and growls:"
8910? "  Can't you read?!":FOR de=1 TO 4000:NEXT:RETURN
8920? "The girl takes the check says:":? "    Just a minute,Sir.":? "..and disappears.": b=1.5:GOSUB 9000
8922? "She's back and she hands me a  hat.": o(17)=50: o(8)=-1:GOTO 400
8930? "A peephole opens in the door.": b=1:GOSUB 9000:? "A rough voice says:  "; 
8932?:INPUT "Whadayawant? "; a$
8936IF LEFT$(a$, 3)<>"sho" THEN ? "The voice snarls:":? "  Get lost!":? "The peephole slams shut.":GOTO 400
8937IF o(21)<>-1 THEN ? "The voice snarls: ":? "Beat it, Bud!":? "The peephole slams shut":GOTO 400
8940? "The doors swings open.The voice says:":? "   Hurry up!": l=8: b=.5:GOSUB 9000
8942? "The door slams shut": b=2:GOSUB 9000:GOTO 200
8950IF LEN(a$)<8 THEN ? CHR$(7); " Too short!":RETURN
8952IF a$<>"18-22-11" THEN ? "I tried but the safe didn't open.":RETURN
8955? "The safe opens.":? "I found something!": o(19)=5: o$(6)="safe,open":RETURN
8990HOME:?:? " A waiter suddenly appears"
8992?:? " He says:":? "     This way please.":FOR x=1 TO 3000:?:? "He gives me a menu and leaves."
8993? "===============================":IF o(22)<>-1 THEN  o(22)=-1: ca=ca+1
8995 l=25: b=1.5
9000FOR de=1 TO 3500*b:NEXT:RETURN
9100? "Oh man..":? "now I smell like the trash can":? "I quit for the day.I'm going   home to take a shower."
9110?:? "Do you want to play again? "; :GET a$:IF a$="Y" OR a$="y" THEN RESTORE:GOTO 110
9120POKE 17059, 0:POKE 17115, 240:POKE 17126, 15:TEXT:END
9200? "Excellent job. You receive a   commendation from I.M.Debos fora job well done!!":?:GOTO 9110
9250? "     "; :INVERSE:? " ---------------- ":NORMAL
9252? "     "; :INVERSE:? "  the RUMRUNNER   ":NORMAL:? "     "; :INVERSE:? SPC(18):NORMAL:?
9254? "     "; :INVERSE:? "  A PRIVATE CLUB  ":NORMAL
9255? "     "; :INVERSE:? "  Membership card ":NORMAL
9257? "     "; :INVERSE:? SPC(18):NORMAL:?:? "     "; :INVERSE:? " ---------------- ":NORMAL:?
9259GOTO 400
9260? "A giant redhead grabs me by the neck, and throws me out.":GOTO 400
