0NORMAL:SPEED =255:HOME
1REM *RENEGADE ROBOT II*
2REM *by Joey Latimer*
3REM *August 1985 Family Computing*
4REM *slightly modified by Ann Jones*
10LOMEM :32100
11POKE 17059, 7:POKE 17115, 16:POKE 17126, 16:POKE 16953, 32:TEXT
20VTAB 6:HTAB 10:? "************":VTAB 7:HTAB 10:? "*":VTAB 7:HTAB 21:? "*"
21VTAB 8:HTAB 10:? "*":VTAB 8:HTAB 11:? " RENEGADE":VTAB 8:HTAB 21:? "*"
22VTAB 9:HTAB 10:? "*":VTAB 9:HTAB 11:? " ROBOT II":VTAB 9:HTAB 21:? "*"
23VTAB 10:HTAB 10:? "*":VTAB 10:HTAB 21:? "*":VTAB 11:HTAB 10:? "************"
24FOR p=1 TO 2000:NEXT p
25SPEED =30:?:?:?:?:?:?:?:?:?:?:?:?:?:?:?:?
26SPEED =255:?:? " The underground parking lot    where you work seems just a    little too quiet."
27?:? " Of course,you're still a bit   edgy after your narrow escape  from the RENEGADE ROBOT,but"
28? " still...you have the creepy    feeling that you're being      watched."
29?:? " Suddenly,the hot smell of      machine oil and the hum of     metal wheels confirm your"
30? " worst suspicions:":?:? "   The RENEGADE ROBOT is          back and it's time for         you to get lost!"
31?:?:? " (PRESS RIGHT TRIGGER BUTTON)"
32IF PDL(9)<>1 THEN 32
33?:?:?:? " But luck's really running      against you this time--the     doors of the parking lot all"
34? " seem to be locked!"
35?:? " Don't give up hope. One of     the doors may still be open.   There are six doors around"
36? " the perimeter of the lot,and   you may have to try all of     them to find out which one"
37? " offers you an escape."
38?:? " Jiggling door handles and      keeping clear of the RENEGADE  ROBOT'S steel pincers isn't"
39? " going to be easy,however."
40?:?:? " (PRESS RIGHT TRIGGER BUTTON)"
41IF PDL(9)<>1 THEN 41
42?:?:?:? " To make things more            interesting,the longer you     remain in the lot (and out of"
43? " the robot's clutches),the      more points you'll gain."
44?:? " Since the robot always heads   more or less towards your      position,you may be able"
45? " to use the parked cars to      trap him--but watch out! He's  smarter than he looks,and may"
46? " do something unpredictable at  any time!"
47?:?:?:?:?:? " (PRESS RIGHT TRIGGER BUTTON        TO BEGIN THE GAME!)"
48IF PDL(9)<>1 THEN 48
50DIM dr(6, 2): rv=.5
60FOR i=1 TO 9: bl$=bl$+CHR$(32):NEXT i
65FOR i=1 TO 6:READ dr(i, 1), dr(i, 2):NEXT i
70HOME:GR:COLOR =9
80HLIN 0, 39 AT 0:HLIN 0, 39 AT 1
90HLIN 0, 39 AT 38:HLIN 0, 39 AT 39
100VLIN 2, 37 AT 0:VLIN 2, 37 AT 1
110VLIN 2, 37 AT 38:VLIN 2, 37 AT 39:COLOR =8
120FOR i=1 TO 6:PLOT dr(i, 1), dr(i, 2):NEXT i
130FOR i=3 TO 35 STEP 2:FOR j=3 TO 36
140IF RND(1)>rv THEN COLOR =INT(RND(1)*7)+1:PLOT j, i
150NEXT j, i
160VTAB 21:HTAB 11:? "SCORE:"
170 px=INT(RND(1)*10)+2: py=(INT(RND(1)*18)+1)*2
180 rx=INT(RND(1)*10)+26: ry=(INT(RND(1)*18)+1)*2
190 sc=0: do=INT(RND(1)*6)+1: ts=RND(1)*500+500
200COLOR =15:PLOT px, py
210COLOR =11:PLOT rx, ry
220 j=PDL(5)
230 nx=px+(j=2 OR j=3 OR j=6)-(j>6)
240 ny=py+(j=4 OR j=6 OR j=12)-(j=1 OR j=3 OR j=9)
250IF px=nx AND py=ny THEN 380
260IF nx<1 OR nx>38 OR ny<1 OR ny>38 THEN 490
270 p=SCRN(nx, ny):IF p=0 THEN 320
280IF p<>8 THEN 380
290VTAB 22:HTAB 1
300IF nx<>dr(do, 1) OR ny<>dr(do, 2) THEN ? "LOCKED!":GOTO 360
310? "UNLOCKED!"
320COLOR =8*(px=dr(do, 1) AND py=dr(do, 2))
330PLOT px, py
340COLOR =15:PLOT nx, ny: px=nx: py=ny
350IF p<>8 THEN 380
360FOR d=1 TO 200:NEXT d
370VTAB 22:HTAB 1:? SPC(9)
380IF sc<ts THEN 480
390 qx=rx+SGN(px-rx): qy=ry+SGN(py-ry): f=1
400 p=SCRN(qx, qy):IF p=0 OR p=15 THEN 450
410 d=2*INT(RND(1)*2)-1
420IF f THEN  qx=rx+d: qy=ry:GOTO 440
430 qy=ry+d: qx=rx
440 f= NOT f:GOTO 400
450COLOR =0:PLOT rx, ry:COLOR =11:PLOT qx, qy
460IF p=15 THEN 520
470 rx=qx: ry=qy
480 sc=sc+10:HTAB 17:VTAB 21:? sc:GOTO 220
490TEXT:HOME:FOR i=1 TO 7
500? CHR$(7); :FOR d=1 TO 50:NEXT d, i
510? "YOU ESCAPED!":GOTO 540
520TEXT:HOME:? CHR$(7); 
530? "SORRY, YOU WERE CAUGHT!"
540?:? "YOUR SCORE WAS "; sc
550IF sc>hs THEN  hs=sc
560?:? "THE HIGH SCORE IS "; hs
570?:? " PRESS RIGHT TRIGGER TO PLAY    AGAIN OR LEFT TRIGGER TO QUIT."
590IF PDL(9)=1 THEN 70
600IF PDL(7)<>1 THEN 590
610POKE 16953, 95:SPEED =255:HOME:END
1000DATA  20,1,38,12,38,26,20,38,1,12,1,26
7777REM ********************
7778REM  Increasing or decreasing the number of obstacles in the robot's path makes RENEGADE ROBOT II easier or more dificult to 
7779REM  play. The variable "rv" in line 50 controls the random process that places obstacles on the screen. You may adjust
7780REM  gameplay as you like by changing "rv" to any decimal number between 0 (most obstacles) and 1 (no obstacles).
