
0NORMAL:SPEED =255:HOME
1REM ***RENEGADE ROBOT***
2REM ***by Joey Latimer***
3REM ***August 1984 Family Computing***
4REM ***slightly modified by Ann Jones***
10LOMEM :32100
11POKE 17059, 7:POKE 17115, 16:POKE 17126, 16:POKE 16953, 32:TEXT
20VTAB 6:HTAB 10:? "************":VTAB 7:HTAB 10:? "*":VTAB 7:HTAB 21:? "*"
21VTAB 8:HTAB 10:? "*":VTAB 8:HTAB 11:? " RENEGADE":VTAB 8:HTAB 21:? "*"
22VTAB 9:HTAB 10:? "*":VTAB 9:HTAB 11:? "  ROBOT!":VTAB 9:HTAB 21:? "*"
23VTAB 10:HTAB 10:? "*":VTAB 10:HTAB 21:? "*":VTAB 11:HTAB 10:? "************"
24FOR p=1 TO 2000:NEXT p
25SPEED =30:?:?:?:?:?:?:?:?:?:?:?:?:?:?:?:?
26SPEED =255:?:? " The top-secret building where  you work is guarded by a       robot."
27?:? " One day you arrive at work     and find the robot missing.    Puzzled,you enter the build-"
28? " ing and immediately sense      that something has gone wrong."
29? " Strange noises are coming      from a distant corridor. You   investigate and discover that"
30? " it's the sound of the robot,   twirling around in circles and crashing into walls."
31? "  "; CHR$(34); "It's wires must have"
32? "  snapped!"; CHR$(34); " you think to"
33? "  yourself. "; CHR$(34); "It's gone"
34? "  completely berserk!"; CHR$(34)
35?:? " (PRESS RIGHT TRIGGER BUTTON)"
36IF PDL(9)<>1 THEN 36
37?:?:?:? " The instant the robot senses   your presence it comes after   you,red eyes flashing madly."
38?:? " Your only hope is to reach     the center of the building     and turn off the power"
39? " switch that controls the       robot before it catches you."
40?:? " It won't be easy:The robot is  smart and not only knows the   floorplan by heart,but also"
41? " why you're heading toward the  building's center."
42?:? "  You'd better get started.":? "    Time is running out!"
43?:?:? "     -TO BEGIN THE GAME-"
44? "  PRESS RIGHT TRIGGER BUTTON"
45IF PDL(9)<>1 THEN 45
46CLEAR
50GR
51READ s, hr, hc, f
52COLOR =3
53PLOT 19, 17
54PLOT 19, 18
60PLOT 20, 17
70PLOT 20, 18
80COLOR =7
90FOR x=1 TO 24
100READ a, b, c
110FOR y=a TO b
120IF x<=12 THEN PLOT c, y:GOTO 140
130PLOT y, c
140NEXT y
150NEXT x
160 h1=INT(RND(1)*22)
170 h2=INT(RND(1)*8)+32*(RND(1)>.5)
180VTAB 22
190HTAB 15
200? s; " "
210 s=s-1
220 j=PDL(5)
230 ro=h1+(j=4 OR j=6 OR j=12)-(j=1 OR j=3 OR j=9)
240 co=h2+(j=2 OR j=3 OR j=6)-(j=8 OR j=9 OR j=12)
250 ro=ro-(ro>39)+(ro<0)
260 co=co-(co>39)+(co<0)
270IF SCRN(co, ro)=7 THEN  ro=h1: co=h2:GOTO 350
280COLOR =0
290PLOT h2, h1
300COLOR =13
310PLOT co, ro
320 h1=ro
330 h2=co
340IF (ro=17 OR ro=18) AND (co=19 OR co=20) THEN 530
350 ra=hr+(ro>hr)-(ro<hr)
360 ca=hc+(co>hc)-(co<hc)
370 ra=ra-(ra>39)-(ra<0)
380 ca=ca-(ca>39)-(ca<0)
390IF SCRN(ca, ra)<>3 AND SCRN(ca, ra)<>7 THEN 450
400 d=2*INT(RND(1)*2)-1
410IF f THEN  ra=hr+d: ca=hc:GOTO 430
420 ca=hc+d: ra=hr
430 f= NOT f
440GOTO 370
450COLOR =0
460PLOT hc, hr
470COLOR =11
480PLOT ca, ra
490 hc=ca
500 hr=ra
510IF ca=co AND ra=ro THEN 610
520GOTO 180
530TEXT
540IF s>hs THEN  hs=s
550FOR t=1 TO 50
560? CHR$(7); " YOU DID IT! "; 
570NEXT t
580HOME
590? " YOUR SCORE IS "; s; "."
600GOTO 630
610TEXT
620? CHR$(7); " SORRY,YOU WERE CAUGHT!"
630? " THE HIGH SCORE IS "; hs; "."
640?:?:? "        TO PLAY AGAIN":? "  PRESS RIGHT TRIGGER BUTTON"
641?:? "        TO END THE GAME":? "  PRESS LEFT TRIGGER BUTTON"
642IF PDL(9)<>1 AND PDL(7)<>1 THEN 642
643IF PDL(9)=1 THEN GOTO 650
644IF PDL(7)=1 THEN TEXT:POKE 16953, 95:HOME:END
650RESTORE:GOTO 50
700DATA  1000,25,20,0  
710DATA  6,18,8,20,33,8,12,13,12,15,24,12,26  
720DATA  27,12,16,22,16,16,22,23,12,13,27,15  
730DATA  24,27,26,27,27,6,18,31,20,33,31,10,19
740DATA  6,12,29,6,12,14,12,16,23,12,25,27,12 
750DATA  16,23,16,18,21,22,12,14,27,16,23,27
760DATA  25,27,27,10,19,33,21,29,33   
770END

