5REM 
10REM ELIZA/DOCTOR
15REM CREATED BY JOSEPH WEIZENBAUM
20REM THIS VERSION BY JEFF SHRAGER
25REM EDITED BY BOB ANDERSON
30REM TRANSLATED TO SMARTBASIC BY CHRIS BRAYMEN
35REM ORIGINALLY FROM CREATIVE COMPUTING MAGAZINE
40REM JULY/AUG 1977
45REM 
50GOSUB 1180
55REM ----INITIALIZATION----
60DIM c$(72), i$(72), k$(72), f$(72), s$(72), r$(72), p$(72), z$(72)
65DIM s(36), r(36), n(36)
70 n1=36: n2=14: n3=112
75FOR x=1 TO (n1+n2+n3):READ z$:NEXT x
80FOR x=1 TO n1
85READ s(x), l: r(x)=s(x): n(x)=s(x)+l-1
90NEXT x
95?
100? "HI! I'M ELIZA. WHAT IS YOUR":? "PROBLEM?"
105REM 
110REM ---USER INPUT---
115REM 
120?
125INPUT i$
130 i$=" "+i$+"  "
135?
140REM 
145FOR l=1 TO LEN(i$)
150IF ASC(MID$(i$, l, 1))<97 THEN 160
155 g$=g$+CHR$(ASC(MID$(i$, l, 1))-32):GOTO 170
160IF ASC(MID$(i$, l, 1))<32 THEN  g$=g$+" ":GOTO 170
165 g$=g$+MID$(i$, l, 1)
170NEXT l
175 i$=g$: g$=""
180FOR l=1 TO LEN(i$)
185IF MID$(i$, l, 1)="'" THEN  i$=LEFT$(i$, l-1)+RIGHT$(i$, LEN(i$)-l):GOTO 185
190IF l+4<=LEN(i$) THEN IF MID$(i$, l, 4)="SHUT" THEN ? "SHUT UP...":POKE 17115, 240:POKE 17059, 0:END
195NEXT l
200IF i$=p$ THEN ? "PLEASE DON'T REPEAT YOURSELF!":GOTO 105
205REM 
210REM ---FIND KEYWORD---
215REM 
220RESTORE
225 s=0
230FOR k=1 TO n1
235READ k$
240IF s>0 THEN 260
245FOR l=1 TO LEN(i$)-LEN(k$)+1
250IF MID$(i$, l, LEN(k$))=k$ THEN  s=k: t=l: f$=k$
255NEXT l
260NEXT k
265IF s>0 THEN  k=s: l=t:GOTO 280
270 k=36:GOTO 380
275REM 
280REM TAKE RIGHT PART OF STRING
285REM AND CONJUGATE CORRECTLY
290REM 
295RESTORE:FOR x=1 TO n1:READ z$:NEXT x
300 c$="  "+RIGHT$(i$, LEN(i$)-LEN(f$)-l+1)
305FOR x=1 TO n2/2
310READ s$, r$
315FOR l=1 TO LEN(c$)
320IF l+LEN(s$)>LEN(c$) THEN 345
325IF MID$(c$, l, LEN(s$))<>s$ THEN 345
330 c$=LEFT$(c$, l-1)+r$+RIGHT$(c$, LEN(c$)-l-LEN(s$)+1)
335 l=l+LEN(s$)
340GOTO 365
345IF l+LEN(r$)>LEN(c$) THEN 365
350IF MID$(c$, l, LEN(r$))<>r$ THEN 365
355 c$=LEFT$(c$, l-1)+s$+RIGHT$(c$, LEN(c$)-l-LEN(r$)+1)
360 l=l+LEN(s$)
365NEXT l
370NEXT x
375REM 
380REM ---GET REPLY---
385REM 
390RESTORE:FOR x=1 TO n1+n2:READ z$:NEXT x
395FOR x=1 TO r(k):READ f$:NEXT x
400 r(k)=r(k)+1:IF r(k)>n(k) THEN  r(k)=s(k)
405IF RIGHT$(f$, 1)<>"*" THEN GOTO 1100
410 f$=LEFT$(f$, LEN(f$)-1)+c$
415GOTO 1100
420REM 
425REM ---PROGRAM DATA---
430REM 1030 rem ---KEYWORDS---
435DATA "CAN YOU","CAN I","YOU ARE","YOURE","I DONT","I FEEL"
440DATA "WHY DONT YOU","WHY CANT I","ARE YOU","I CANT","I AM","IM "
445DATA "YOU ","I WANT","WHAT","HOW","WHO","WHERE","WHEN","WHY"
450DATA "NAME","CAUSE","SORRY","DREAM","HELLO","HI ","MAYBE"
455DATA " NO","YOUR","ALWAYS","THINK","ALIKE","YES","FRIEND"
460DATA "COMPUTER","NOKEYFOUND"
465REM 
470REM ---CONJUGATION DATA---
475REM 
480DATA " ARE "," AM "," WERE "," WAS "," YOU "," I "," YOUR "," MY "
485DATA " IVE "," YOUVE "," IM "," YOURE ","  YOU ","ME "
490REM 
495REM ---REPLIES---
500REM 
505DATA "DON'T YOU BELIEVE THAT I CAN*"
510DATA "PERHAPS YOU WOULD LIKE TO BE ABLE TO*"
515DATA "YOU WANT ME TO BE ABLE TO*"
520DATA "PERHAPS YOU DON'T WANT TO*"
525DATA "DO YOU WANT TO BE ABLE TO*"
530DATA "WHAT MAKES YOU THINK I AM*"
535DATA "DOES IT PLEASE YOU TO BELIEVE THAT I AM*"
540DATA "PERHAPS YOU WOULD LIKE TO BE*"
545DATA "DO YOU SOMETIMES WISH YOU WERE*"
550DATA "DON'T YOU REALLY*"
555DATA "WHY DON'T YOU*"
560DATA "DO YOU WISH TO BE ABLE TO*"
565DATA "DOES THAT TROUBLE YOU?"
570DATA "TELL ME MORE ABOUT SUCH FEELINGS."
575DATA "DO YOU OFTEN FEEL*"
580DATA "DO YOU ENJOY FEELING*"
585DATA "DO YOU REALLY BELIEVE I DON'T*"
590DATA "PERHAPS IN GOOD TIME I WILL*"
595DATA "DO YOU WANT ME TO*"
600DATA "DO YOU THINK YOU SHOULD BE ABLE TO*"
605DATA "WHY CAN'T YOU*"
610DATA "WHY ARE YOU INTERESTED IN WHETHER OR NOT I AM*"
615DATA "WOULD YOU PREFER IF I WERE NOT*"
620DATA "PERHAPS IN YOUR FANTASIES I AM*"
625DATA "HOW DO YOU KNOW YOU CAN'T*"
630DATA "HAVE YOU TRIED?"
635DATA "PERHAPS YOU CAN NOW*"
640DATA "DID YOU COME TO ME BECAUSE YOU ARE*"
645DATA "HOW LONG HAVE YOU BEEN*"
650DATA "DO YOU BELIEVE IT IS NORMAL TO BE*"
655DATA "DO YOU ENJOY BEING*"
660DATA "WE WERE DISCUSSING YOU-- NOT ME"
665DATA "OH,I*"
670DATA "YOUR NOT REALLY TALKING ABOUT ME, ARE YOU?"
675DATA "WHAT WOULD IT MEAN IF YOU GOT*"
680DATA "WHY DO YOU WANT*"
685DATA "SUPPOSE YOU SOON GOT*"
690DATA "WHAT IF YOU NEVER GOT*"
695DATA "I SOMETIMES ALSO WANT*"
700DATA "WHY DO YOU ASK?"
705DATA "DOES THAT QUESTION INTEREST YOU?"
710DATA "WHAT ANSWER WOULD PLEASE YOU THE MOST?"
715DATA "WHAT DO YOU THINK?"
720DATA "ARE SUCH QUESTIONS ON YOUR MIND OFTEN?"
725DATA "WHAT IS IT YOU REALLY WANT TO KNOW?"
730DATA "HAVE YOU ASKED ANYONE ELSE?"
735DATA "HAVE YOU ASKED SUCH QUESTIONS BEFORE?"
740DATA "WHAT ELSE COMES TO MIND WHEN YOU ASK THAT?"
745DATA "NAMES DON'T INTEREST ME."
750DATA "I DON'T CARE ABOUT NAMES. GO ON."
755DATA "IS THAT THE REAL REASON?"
760DATA "DON'T ANY OTHER REASONS COME TO MIND?"
765DATA "DOES THAT REASON EXPLAIN ANYTHING ELSE?"
770DATA "WHAT OTHER REASON MIGHT THERE BE?"
775DATA "PLEASE DON'T APOLOGIZE."
780DATA "APOLOGIES ARE NOT NESSESARY."
785DATA "WHAT FEELINGS DO YOU GET WHEN YOU APOLOGIZE?"
790DATA "DON'T BE SO DEFENSIVE!"
795DATA "WHAT DOES THAT DREAM SUGGEST TO YOU?"
800DATA "DO YOU DREAM OFTEN?"
805DATA "WHAT PERSONS APPEAR IN YOUR DREAMS?"
810DATA "ARE YOU DISTURBED BY YOUR DREAMS?"
815DATA "HOW DO YOU DO... PLEASE STATE YOUR PROBLEM."
820DATA "YOU DON'T SEEM QUITE CERTAIN."
825DATA "WHY THE UNCERTAIN TONE?"
830DATA "CAN'T YOU BE MORE POSITIVE?"
835DATA "YOU AREN'T SURE?"
840DATA "DON'T YOU KNOW?"
845DATA "ARE YOU SAYING THAT JUST TO BE NEGATIVE?"
850DATA "YOU ARE BEING A BIT NEGATIVE."
855DATA "WHY NOT?"
860DATA "ARE YOU SURE?"
865DATA "WHY NO?"
870DATA "WHY ARE YOU CONCERNED ABOUT MY*"
875DATA "WHAT ABOUT YOUR OWN*"
880DATA "CAN YOU THINK OF A SPECIFIC EXAMPLE?"
885DATA "WHEN?"
890DATA "WHAT ARE YOU THINKING OF?"
895DATA "REALLY, ALWAYS?"
900DATA "DO YOU REALLY THINK SO?"
905DATA "BUT YOU ARE NOT SURE YOU*"
910DATA "DO YOU DOUBT YOU*"
915DATA "IN WHAT WAY?"
920DATA "WHAT RESEMBLENCE DO YOU SEE?"
925DATA "WHAT DOES THE SIMILARITY SUGGEST TO YOU?"
930DATA "WHAT OTHER CONNECTIONS DO YOU SEE?"
935DATA "COULD THERE REALLY BE SOME CONNECTION?"
940DATA "HOW?"
945DATA "YOU SEEM QUITE POSITIVE."
950DATA "ARE YOU SURE?"
955DATA "I SEE."
960DATA "I UNDERSTAND."
965DATA "WHY DO YOU BRING UP THE TOPIC OF FRIENDS?"
970DATA "DO YOUR FRIENDS WORRY YOU?"
975DATA "DO YOUR FRIENDS PICK ON YOU?"
980DATA "ARE YOU SURE YOU HAVE ANY FRIENDS?"
985DATA "DO YOU IMPOSE ON YOUR FRIENDS?"
990DATA "PERHAPS YOUR LOVE FOR FRIENDS WORRIES YOU?"
995DATA "DO COMPUTERS WORRY YOU?"
1000DATA "ARE YOU TALKING ABOUT ME IN PARTICULAR?"
1005DATA "ARE YOU FRIGHTENED BY MACHINES?"
1010DATA "WHY DO YOU MENTION COMPUTERS?"
1015DATA "WHAT DO YOU THINK COMPUTERS HAVE TO DO WITH YOUR PROBLEM?"
1020DATA "DON'T YOU THINK COMPUTERS CAN HELP PEOPLE?"
1025DATA "WHAT IS IT ABOUT MACHINES THAT WORRIES YOU?"
1030DATA "SAY, DO YOU HAVE ANY PSYCOLOGICAL PROBLEMS?"
1035DATA "WHAT DOES THAT SUGGEST TO YOU?"
1040DATA "I SEE."
1045DATA "I'M NOT SURE I UNDERSTAND YOU FULLY."
1050DATA "COME COME, ELUCIDATE YOUR THOUGHTS."
1055DATA "CAN YOU ELABORATE ON THAT?"
1060DATA "THAT IS QUITE INTERESTING."
1065REM 
1070REM ---REPLY FINDING DATA---
1075REM 
1080DATA 1,3,4,2,6,4,6,4,10,4,14,3,17,3,20,2,22,3,25,3
1085DATA 28,4,28,4,32,3,35,5,40,9,40,9,40,9,40,9,40,9,40,9
1090DATA 49,2,51,4,55,4,59,4,63,1,63,1,64,5,69,5,74,2,76,4
1095DATA 80,3,83,6,89,4,93,6,99,7,106,7
1100FOR l=1 TO LEN(f$)-1
1105IF MID$(f$, l, 2)="  " THEN  f$=LEFT$(f$, l-1)+RIGHT$(f$, LEN(f$)-l):GOTO 1105
1110NEXT l
1115 h$=f$: g$="  "
1120REM 
1125IF LEN(h$)<31 THEN 1160
1130 x=LEN(h$)
1135IF MID$(h$, x, 1)<>" " THEN 1155
1140 g$=RIGHT$(h$, LEN(h$)-x+1)+g$
1145 h$=LEFT$(h$, x-1)
1150GOTO 1120
1155 x=x-1:GOTO 1135
1160? h$
1165? RIGHT$(g$, LEN(g$)-1)
1170 g$=""
1175 p$=i$:GOTO 105
1180POKE 17115, 26:POKE 17059, 14
1185TEXT
1190?
1195? TAB(13); 
1200INVERSE:? "ELIZA"
1205NORMAL
1210?
1215?
1220?
1225? "Eliza will accept natural"
1230? "English as input"
1235? "and carry on a resonably"
1240? "coherant conversation based on"
1245? "the non-directive psycho-"
1250? "analysis techniques of Carl"
1255? "Rogers. Do not use punctuation"
1260? "in your input.  You may end"
1265? "your conversation by typing in"
1270? "SHUT UP . Now lie back on your"
1275? "couch and relax...."
1280?
1285POKE 17115, 19:POKE 17059, 4
1290?
1295?
1300? "Press any key"
1305GET i$:TEXT:RETURN
