
10REM  ********************
11REM  ***              ***
12REM  ***    CRAPS     ***
13REM  ***              ***
14REM  ********************
15REM  ** Modified for   **
16REM  **     ADAM       **
17REM  ** by W.L. Osburn **
18REM  ********************
19REM  ****** 12/8/87******
20GOSUB 1000:REM INSTS
30GOSUB 2000:REM SETUP
40GOSUB 3000:REM PLAY!
50GOSUB 4000:REM !END!
55SPEED =255
60END
100POKE 12185, 239
1000REM ***
1001REM *** INSTS
1010TEXT:NORMAL:HOME
1020VTAB 3:HTAB 13:? "*** CRAPS ***"
1030VTAB 5
1031? "   THIS IS A DICE GAME CALLED             **CRAPS**"
1035?
1040? "TO PLAY, YOU WAGER A PORTION OFYOUR MONEY ON A ROLL OF THE    DICE. HERE ARE THE RULES...."
1045?
1050? "YOU WIN IF THE FIRST ROLL IS   EITHER 7 OR 11. CONVERSELY, YOULOSE IF THE FIRST ROLL IS 2,3, OR 12."
1060?
1065? "IF YOU GET A 4,5,6,8,9,OR 10 ONYOUR FIRST ROLL, IT IS REFERREDTO AS YOUR *POINT*. YOU MUST   CONTINUE ROLLING "; 
1070? "UNTIL YOU:    1) ROLL A 7, WHICH IS CALLED   *CRAPPING OUT* WHEREBY YOU LOSEOR 2) YOU ROLL A NUMBER EQUAL  TO YOUR POINT...YOU WIN!"
1075?
1078INPUT "  PRESS RETURN WHEN READY TO             CONTINUE:"; ans$
1080HOME:VTAB 3:HTAB 13:? "*** CRAPS ***"
1100VTAB 12
1110? "TO QUIT THE GAME, BET 0 DOLLARS "
1990VTAB 23:INPUT "  PRESS RETURN WHEN READY TO             CONTINUE:"; ans$
1995RETURN
2000REM  
2001REM    *** SETUP
2010GR
2011COLOR =15
2020 mny=1500
2022HLIN 0, 39 AT 0:HLIN 0, 39 AT 39
2023VLIN 0, 39 AT 0:VLIN 0, 39 AT 39
2190RETURN
2200 d1=INT(RND(1)*6)+1: d2=INT(RND(1)*6)+1
2210GOSUB 2300:GOSUB 2310
2220IF PEEK(64885)<128 THEN 2200
2230POKE 64885, 0:RETURN
2300 dd=d1: dx=10:GOTO 2320
2310 dd=d2: dx=24:GOTO 2320
2320COLOR =INT(RND(1)*14)+1
2325FOR i=20 TO 26:HLIN dx, dx+6 AT i:NEXT
2330COLOR =15:ON dd GOTO 2331, 2332, 2333, 2334, 2335, 2336
2331PLOT dx+3, 23:GOTO 2340
2332PLOT dx+1, 21:PLOT dx+5, 25:GOTO 2340
2333PLOT dx+1, 21:PLOT dx+3, 23:PLOT dx+5, 25:GOTO 2340
2334PLOT dx+1, 21:PLOT dx+5, 21:PLOT dx+1, 25:PLOT dx+5, 25:GOTO 2340
2335PLOT dx+1, 21:PLOT dx+5, 21:PLOT dx+1, 25:PLOT dx+5, 25:PLOT dx+3, 23:GOTO 2340
2336PLOT dx+1, 21:PLOT dx+5, 21:PLOT dx+1, 25:PLOT dx+5, 25:PLOT dx+1, 23:PLOT dx+5, 23:GOTO 2340
2340FOR i=1 TO 5:? CHR$(7):NEXT:RETURN
3000REM  
3001REM    *** PLAY
3010HOME:? "YOU HAVE "; mny; " DOLLARS"
3020INPUT "HOW MUCH WILL YOU RISK ON THIS BET? "; ans$
3021 ans=VAL(ans$)
3022IF ans<0 OR ans>mny OR ans<>INT(ans) THEN 3010
3023IF ans=0 THEN RETURN
3025HOME:? "BET: "; ans; "(ROLLING ...)"
3030? "<PRESS ANY KEY TO STOP THE ROLL>"
3040GOSUB 2200
3050HOME:? "ROLLED: "; d1+d2
3060IF d1+d2=7 OR d1+d2=11 THEN ? "YOU WON THAT     TOSS     ...":FOR pa=1 TO 1500:NEXT pa:GOTO 3200
3061? "YOUR POINT IS "; d1+d2: pt=d1+d2:FOR pa=1 TO 1200:NEXT pa
3065HOME:? "BET: "; ans; " PT: "; pt; "   (ROLLING           AGAIN...)"
3066? "<PRESS ANY KEY TO STOP THE ROLL>":GOSUB 2200
3070HOME:? "ROLLED: "; d1+d2
3080IF d1+d2=7 THEN ? "YOU CRAPPED OUT ...":FOR pa=1 TO 1500:NEXT pa:GOTO 3100
3085IF d1+d2=pt THEN ? "YOU GOT YOUR POINT !!!":FOR pa=1 TO 1500:NEXT pa:GOTO 3200
3090? "YOU MUST ROLL AGAIN...":FOR pa=1 TO 1200:NEXT pa:GOTO 3065
3100 mny=mny-ans:IF mny=0 THEN RETURN
3110GOTO 3010
3200 mny=mny+ans:GOTO 3010
4000REM  ***
4001REM  *** END
4010FOR i=0 TO 39:COLOR =INT(RND(1)*15)+1:HLIN 0, 39 AT i:HLIN 0, 39 AT 39-i:VLIN 0, 39 AT i:VLIN 0, 39 AT 39-i:? CHR$(7):? CHR$(7):? CHR$(
4020FOR pa=1 TO 1500:NEXT pa
4025SPEED =180
4030HOME:? "  YOU STOPPED WITH "; mny; " DOLLARS"
4040IF mny<100 THEN ? "   BETTER STICK TO THE SLOT              MACHINES!":RETURN
4041IF mny<500 THEN ? "NOT SO GOOD":RETURN
4042IF mny<1500 THEN ? "NOT BAD AT ALL....":RETURN
4043? "THAT'S GREAT! "; 
4044IF mny>6000 THEN ? "WOW, WHATTA ROLL!!!"
4045RETURN
