9HOME
10REM                                        TIM`S  CHATEAU GILLIARD
11REM                          UPGRADED VERSION
12? "PLEASE WAIT WHILE I "
13? "SET UP THE CASTLE..."
14FOR z=1 TO 9000:NEXT z
20GOSUB 2600:REM                                     initialise
30GOSUB 160
40IF ro<>28 THEN 30
50?:? "YOU`VE DONE IT!!":GOSUB 3520:? "THAT WAS THE EXIT FROM THE CASTLE"
60GOSUB 3520
70?:? "YOU HAVE SUCCEEDED, "; n$; "!"
80?:? " YOU MANAGED TO GET OUT OF THE CASTLE"
90GOSUB 3520
100?:? "WELL DONE!"
110GOSUB 3520
120?:? "YOUR SCORE IS"; 
130? 3*tally+5*strength+2*wealth+food+30; mk
140END
150REM                                    ***********************
160REM                                     major handling routine
170 strength=strength-5
175INVERSE
180IF strenght<10 THEN ? "WARNING,"; n$; ", YOUR STRENGHT":? " IS RUNNING LOW":?
185NORMAL
190IF strength<1 THEN 2300:REM                                     DEATH
200 tally=tally+1
210? n$; ", YOUR STRENGTH IS"; strength
220IF wealth>0 THEN ? "YOU HAVE $"; wealth
230IF food>0 THEN ? " YOUR PROVISIONS SACK HOLDS"; food; "UNITS OF FOOD"
240IF suit=1 THEN ? "YOU ARE WEARING ARMOR"
250IF axe=0 AND sword=0 AND amulet=0 THEN 320
260? "YOU ARE CARRING "; 
270IF axe=1 THEN ? "AN AXE "; 
280IF sword=1 THEN ? "A SWORD "; 
290IF sword+axe>0 AND amulet=1 THEN ? "AND "; 
300IF amulet=1 THEN ? "THE MAGIC AMULET"
310?
320IF light=0 THEN ? "IT IS TOO DARK TO SEE ANYTHING"
330IF light=1 THEN GOSUB 990:REM                                     room decription
340 k=a(ro, 7):REM                                     k is set to contents of room
350IF k=0 THEN 440:REM                                     room is empty k=0 then 440:rem ROOM IS EMPTY
355 m=RND(1)
357IF k>9 AND m<=.5 THEN ? "THERE ARE GEMS HERE WORTH $"; k:GOTO 440
360IF k>9 THEN ? "THERE IS TREASURE HERE WORTH $"; k:GOTO 440
370?:?:? "DANGER...THERE IS A MONSTER HERE....":GOSUB 3520
380IF k=-1 THEN  m$="FEROCIOUS WEREWOLF": ff=5
390IF k=-2 THEN  m$="FANATICAL FLESHGORGER": ff=10
400IF k=-3 THEN  m$="MALOVENTY MALDEMER": ff=15
410IF k=-4 THEN  m$="DEVASTATING ICE`DRAGON": ff=20
415IF k=-5 THEN  m$="                 HORRENDOUS HODGEPODGER": ff=25
416IF k=-6 THEN  m$="                 GHASTLY GREUSOMENESS": ff=30
420?:? "IT IS A "; m$
430?:? "THE DANGER LEVEL IS"; ff; "!!"
440GOSUB 3520
450?:?:? "WHAT DO YOU WANT TO DO"; 
460GET a$: a$=LEFT$(a$, 1)
470IF k<0 AND a$<>"f" AND a$<>"r" THEN 460
480?:?:? "---------------------------":?
490IF a$="q" THEN 120
495IF a$="h" THEN GOSUB 9000
500IF a$="n" AND a(ro, 1)=0 THEN ? " NO EXIT THAT WAY":GOTO 440
510IF a$="s" AND a(ro, 2)=0 THEN ? " THERE IS NO EXIT SOUTH":GOTO 440
520IF a$="e" AND a(ro, 3)=0 THEN ? "YOU CANNOT GO IN THAT DIRECTION":GOTO 440
530IF a$="w" AND a(ro, 4)=0 THEN ? " YOU CANNOT MOVE THROUGH SOLID STONE":GOTO 440
540IF a$="u" AND a(ro, 5)=0 THEN ? "THERE IS NO WAY UP FROM HERE":GOTO 440
550IF a$="d" AND a(ro, 6)=0 THEN ? "YOU CANNOT DESCEND FROM HERE":GOTO 440
560IF a$="r" AND RND(1)>.5 THEN 2420
570IF a$="r" THEN ? "WHICH WAY DO YOU WANT TO RUN,CHICKEN?":GOTO 460
580IF a$="f" AND a(ro, 7)>-1 THEN ? "THERE IS NOTHING TO FIGHT HERE":GOTO 440
590IF a$="i" THEN GOSUB 3010:RETURN
600IF a$="c" AND food=0 THEN ? "YOU HAVE NO FOOD":GOTO 440
610IF a$="p" THEN GOSUB 2350:RETURN
620IF a$="f" THEN 730
622IF a$="m" AND amulet=0 THEN ? " YOU DON`T HAVE THE AMULET":GOTO 440
625IF a$="m" THEN FOR j=1 TO 30:? TAB(j); "*":NEXT j
630IF a$="m" THEN  ro=INT(RND(1)*27)+1:IF ro=6 OR ro=11 THEN 630:IF ro<>6 OR 11 THEN 710
640IF a$="c" THEN GOSUB 2480:RETURN
650IF a$="n" THEN  ro=a(ro, 1)
660IF a$="s" THEN  ro=a(ro, 2)
670IF a$="e" THEN  ro=a(ro, 3)
680IF a$="w" THEN  ro=a(ro, 4)
690IF a$="u" THEN  ro=a(ro, 5)
700IF a$="d" THEN  ro=a(ro, 6)
705IF a$="t" THEN ? "     YOUR TALLY SO FAR IS"; 3*tally+5*strength+2*wealth+food+30*mk
706IF a$="t" AND rnd>.5 THEN ?:? "YOU HAVE KILLED"; mk; " MONSTERS SO FAR..."
710RETURN
730REM                                   fight
750? " PRESS ANY KEY TO                    FIGHT. "
760GET a$:IF a$="" THEN 760
770IF suit=1 THEN ? "YOUR ARMOR INCREASES YOUR CHANCE OF SUCCESS": ff=3*(INT(ff/4)):GOSUB 3520
780HOME:FOR j=1 TO 6:? "*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*_*":NEXT j
790IF axe=0 AND sword=0 THEN ? "YOU HAVE NO WEAPONS":? "YOU MUST FIGHT WITH YOUR BEAR HANDS": ff=INT(ff+ff/5):GOTO 870
800IF axe=1 AND sword=0 THEN ? "YOU HAVE ONLY AN AXE TO FIGHT WITH": ff=4*INT(ff/5):GOTO 870
810IF axe=0 AND sword=1 THEN ? "YOU MUST FIGHT WITH YOUR SWORD": ff=3*INT(ff/4):GOTO 870
820INPUT "WHICH WEAPON? 1 - axe, 2 - sword"; z
830IF z<1 OR z>2 THEN 820
840IF z=1 THEN  ff=4*INT(ff/5)
850IF z=2 THEN  ff=3*INT(ff/4)
860REM                                  ***********************************
870REM                                   the battle
880?:?
890IF RND(1)>.5 THEN ? m$; " ATTACKS":IF RND(1)<.5 THEN ? "YOU ATTACK"
900GOSUB 3520
905IF rnd>.5 AND light=1 THEN ? "YOUR TOURCH WAS        KNOCKED FROM YOUR HAND": light=0:GOSUB 3520
906IF rnd>.5 AND axe=1 THEN ? "YOU DROPPED YOUR AXE    IN THE HEAT OF THE BATTLE": axe=0: ff=5*INT(ff/4)
907IF rnd>.4 AND sword=1 THEN ? "YOUR SWORD IS KNOCKED FROM YOUR HAND!!!": sword=0: ff=4*INT(ff/3)
910IF RND(1)>.5 THEN ?:? "YOU MANAGED TO WOUND IT": ff=INT(5*ff/6)
911IF rnd<.2 THEN ? "    Aaaaargh!!!":GOSUB 3520:? "RIP! TEAR! RIP!"
912IF rnd>.9 THEN ? "      YOU WANT TO RUN,BUT YOU STAND  YOUR GROUND..."
913IF rnd>.9 THEN ? "     *&%%$#$% $%# !!@ #$$# #$@! "
914IF rnd>.7 THEN ? "      WILL THIS BE A BATTLE TO THE   DEATH???"
915IF rnd>.7 THEN ? "    HIS EYES FLASH FEARFULLY"
916IF rnd>.7 THEN ? "     BLOOD DRIPS FROM HIS CLAWS!"
917IF rnd>.7 THEN ? "    YOU CAN SMELL THE SULPHER ON   HIS BREATH"
918IF rnd>.7 THEN ? "    HE STRIKES YOU WILDLY,MADLY.........."
919IF rnd>.7 THEN ? "    YOU HAVE NEVER FOUGHT AN       OPPONENT LIKE THIS!!"
920GOSUB 3520
930IF RND(1)>.5 THEN ?:? "THE MONSTER WOUNDS YOU!": strength=strength-5
940IF RND(1)>.35 THEN 890
950IF RND(1)*16>ff THEN ?:? "AND YOU MANAGED TO KILL THE "; m$: mk=mk+1:GOTO 970
960?:? "THE "; m$; " DEFETED YOU": strength=INT(strength/2)
970 a(ro, 7)=0:GOSUB 3410:?:?:GOSUB 3520:RETURN
980REM                                 **********************
990REM                                  room descriptions
1000?:? "**************************":?:?
1008IF ro>19 THEN 3644
1010ON ro GOSUB 1040, 1100, 1170, 1230, 1280, 1360, 1410, 1470, 1540, 1620, 1700, 1730, 1790, 1860, 1960, 2030, 2100, 2160, 2230
1020RETURN
1040REM                                  room 1
1041? "YOU ARE OUT ON THE BATTLEMENTS OF THE "
1042? "CHATEAU. THERE IS ONLY ONE WAY  BACK"
1080RETURN
1100REM                                  room 2
1110? "THIS IS AN EERIE ROOM, WHERE    ONCE"
1111? "MAGICIANS CONVORTED WITH EVIL"
1112? "SPRITES AND WEREBEASTS..."
1113? " EXITS LEAD IN THREE DIRECTIONS"
1114? " AN EVIL SMELL COMES FROM THE    SOUTH"
1150RETURN
1170REM                                  room 3
1180? "AN OLD STRAW MATTRESS LIES IN    ONE CORNER...IT HAS BEEN "
1181? " RIPPED APART TO FIND ANY         TREASURE WHICH WAS HIDDEN"
1182? " IN IT.  "
1183? " LIGHT COMES FITFULLY FROM     A WINDOW TO THE NORTH, AND "
1184? "AROUND THE DOORS TO THE SOUTH    EAST AND WEST"
1210RETURN
1230REM                                  room 4
1240? "THIS WOODEN-PANELLED ROOM      MAKES YOU FEEL DAMP AND "
1241? " UNCOMFORTABLE. THERE ARE       THREE DOORS LEADING FROM "
1242? " THIS ROOM, ONE MADE OF IRON.   YOUR SIXTH SENCE WARNS YOU"
1243? " TO CHOOSE CAREFULLY..."
1260RETURN
1280REM                                  room 5
1290? " A SPELL OF LIVING STONE!,     primed to trap the first "
1291? " intruder has been set on       you...with your last seconds "
1292? " of life you have time only     to feel profound regret..."
1293GOSUB 3520
1294GOSUB 3520
1295GOTO 2300
1340RETURN
1360REM                                  room 6
1370? "You are in an L-shaped room    Heavey parchment lines the "
1371? "walls.  You can see through    an archway to the east....      but that is not the only"
1372? " exit from this room"
1390RETURN
1410REM                                  room 7
1420? " There is an archway to the     west, leading to an L-shaped"
1421? " room. A door leads in the      opposite direction."
1450RETURN
1470REM                                  room 8
1480? " This is the chateau`s main     kitchen. Any food left here "
1481? " has long rotted away..."
1482? " A door leads to the north,    and there is one to the west"
1520RETURN
1540REM                                  room 9
1550? "You find yourself in a small   room ,which makes you feel "
1551? "claustrophobic...":?
1552? "There is a picture of a black   dragon painted on the north"
1553? "wall,above the door..."
1600RETURN
1620REM                                  room 10
1630? "A stairwell ends in this room,   which is more of a landing"
1631? " then a room. the door to the   north is made of iron,which   "
1632? " has rusted over the centuries..."
1680RETURN
1700REM                                  room 11
1701? "There is a stone archway to    the north, You are in a very"
1702? " long room."
1703?:? "Fresh air blows down     some stairs"
1704? "You can see doors to the       south and to the east"
1710RETURN
1730REM                                  room 12
1740? "You have entered a room with   swirling , choking smoke."
1741? ""
1742? "You must leave quickly to       remain healthy enough to     continue your chosen quest..."
1770RETURN
1790REM                                  room 13
1800? " there is a mirror in the       corner. do not look at it      or youy will be enfused"
1801? " with THE SPELL OF CHARISMA"
1840RETURN
1860REM                                  room 14
1870? " This room is richly finished,  with a white marble floor."
1871? "Strange foot prints lead to    the two doors from this room.....follow then if you dare"
1940RETURN
1960REM                                  room 15
1970? " You are in a long,long hall,   lined on both sides with rich    red drapes..."
1971? " They are parted halfway down   the east wall where there      is a door."
2010RETURN
2030REM                                  room 16
2040? " Someone has spent a long time    painting this room bright    yellow..."
2041? " You remember that yellow is    the Ancient Oracle`s Color    Of Warning..."
2080RETURN
2100REM                                  room 17
2101? " AS you stumble down the        ladder you fall into the room.   the ladder crashes down      behind you...."
2102? " There is no way back!!!!"
2103? "a small door leads east from    this very cramped room..."
2140RETURN
2160REM                                  room 18
2161? " You find yourself in a hall of mirrors...and see yourself reflected a hundred timesor more"
2170? "...Through the bright glare you can make out doors in all directions... You the mirrors around the east door"
2171? "  are heavily tarnished..."
2210RETURN
2230REM                                  room 19
2231? " You find yourself in a long corridor..."
2240FOR z=1 TO 1000:NEXT z
2241? " Your footsteps echo as you walk "
2280RETURN
2290REM                                 *******************
2300REM                                  dead end
2309INVERSE
2310? "                      "
2311? "    YOU HAVE DIED.... "
2312? "                      "
2313NORMAL
2320GOSUB 3520
2330GOTO 120
2340REM                                 *******************
2350REM                                  pick up treasure
2360IF a(ro, 7)<10 THEN ? "THERE IS NO TREASURE TO PICKUP":GOSUB 3520:RETURN
2370IF light=0 THEN ? "YOU CANNOT SEE WHERE IT IS ":GOSUB 3520:RETURN
2380 wealth=wealth+a(ro, 7)
2390 a(ro, 7)=0
2400RETURN
2420REM                                  UNSUCCESSFUL ATTEMPT TO RUN
2430? "NO YOU MUST STAND AND FIGHT"
2440 a$="f"
2450GOSUB 3520
2460GOTO 590
2480REM                                  eat food
2490HOME
2500IF food<1 THEN RETURN
2510? "YOU HAVE"; food; "UNITS OF FOOD"
2520? "HOW MANY DO YOU WANT TO EAT"; 
2530INPUT z
2540IF z>food THEN 2530
2550 food=INT(food-z)
2560 strength=INT(strength+5*z)
2570GOSUB 3410:HOME
2580RETURN
2600REM                                  initialise
2610HOME
2620 strenght=60+INT(RND(1)*100)
2630 wealth=30+INT(RND(1)*100)
2640 food=0
2650 tally=0
2660 mk=0:REM                                  no. of monsters killed
2670REM                                  ********************
2680REM                                  set up castle
2690DIM a(44, 7)
2700FOR b=1 TO 44
2710FOR c=1 TO 7
2720READ a(b, c)
2730NEXT c
2740NEXT b
2750INPUT "WHAT IS YOUR NAME, EXPLORER         "; n$
2760HOME
2770 ro=27:REM             start
2780 sword=0
2790 amulet=0
2800 axe=0
2810 suit=0
2820 light=0
2830REM                                 ********************
2840REM                                  allot treasure
2850FOR j=1 TO 12
2860 m=INT(RND(1)*44)+1
2870IF m=6 OR m=11 OR a(m, 7)<>0 THEN 2860
2880 a(m, 7)=INT(RND(1)*100)+10
2890NEXT j
2900REM                                 ********************
2910REM                                 allot monsters
2920FOR j=1 TO 6
2930 m=INT(RND(1)*18)+1
2940IF m=6 OR m=11 OR a(m, 7)<>0 THEN 2930
2950 a(m, 7)=-j
2960NEXT j
2970 a(4, 7)=100+INT(RND(1)*100)
2980 a(16, 7)=100+INT(RND(1)*100)
2985 a(26, 7)=100+INT(RND(1)*100)
2986 a(21, 7)=100+INT(RND(1)*100)
2990RETURN
3010REM                                 inventory/provisions
3020? "PROVISIONS & INVENTORY"
3030GOSUB 3260
3040IF wealth<.1 THEN  z=0:GOTO 3130
3050? "YOU CAN BUY                       1 FLAMING TORCH ($15)"
3060? "   2 AXE ($10)"
3070? "   3 SWORD ($20)"
3080? "   4 FOOD ($2 per unit)"
3090? "   5 MAGIC AMULET ($30)"
3100? "   6 SUIT OF ARMOR ($50)"
3110? "   0 to continue..."
3131IF light=1 THEN ? "  YOU HAVE A TORCH "
3132IF axe=1 THEN ? "    YOUR SUPPLIES NOW INCLUDE ONE  AXE"
3133IF sword=1 THEN ? "   YOU SHOULD GUARD YOUR SWORD    WELL"
3134IF amulet=1 THEN ? " THE AMULET WILL AID YOU IN     TIMES OF STRESS"
3135IF suit=1 THEN ? "    YOU LOOK STUPID IN ARMOR!"
3136?:INPUT " ENTER NO. OF ITEM REQUIRED"; z
3137IF z=0 THEN HOME:RETURN
3140IF z=1 THEN  light=1: wealth=wealth-15
3150IF z=2 THEN  axe=1: wealth=wealth-10
3160IF z=3 THEN  sword=1: wealth=wealth-20
3170IF z=5 THEN  amulet=1: wealth=wealth-30
3180IF z=6 THEN  suit=1: wealth=wealth-50
3190IF wealth<0 THEN ? "YOU CHEATED ME!": wealth=0: suit=0: light=0: axe=0: sword=0: amulet=0: food=INT(food/4):GOSUB 3520
3200IF z<>4 THEN 3030
3210INPUT "HOW MANY UNITS OF FOOD"; q: q=INT(q)
3220IF 2*q>wealth THEN ? "YOU HAVEN`T GOT ENOUGH MONEY":GOTO 3210
3230 food=food+q
3240 wealth=wealth-2*q
3250GOTO 3030
3260IF wealth>0 THEN ?:?:? "YOU HAVE $"; wealth
3270IF wealth=0 THEN ? "YOU HAVE NO MONEY":GOSUB 3520:RETURN
3280FOR j=1 TO 4:?:NEXT j
3290RETURN
3300REM                                ********************
3310DATA              1,1,2,1,1,1,0:REM               room 1
3315DATA              0,29,3,1,0,0,0:REM               room 2
3320DATA              0,8,4,2,0,0,0:REM               room 3
3325DATA              0,9,5,3,0,0,0:REM              room 4
3330DATA              5,5,5,5,5,5,0:REM              room 5
3335DATA              0,11,7,30,0,0,0:REM              room 6
3340DATA              0,0,8,6,0,0,0:REM              room 7
3345DATA              3,0,0,7,0,0,0:REM              room 8
3350DATA              4,10,0,0,0,0,0:REM              room 9
3355DATA              9,0,0,0,0,39,0:REM              room 10
3360DATA             6,0,0,0,28,0,0:REM             room 11
3365DATA             0,16,13,0,0,0,0:REM             room 12
3370DATA             0,0,14,12,0,0,0:REM             room 13
3375DATA              0,18,0,13,0,0,0:REM              room 14
3380DATA              0,21,16,0,0,0,0:REM              room 15
3385DATA              12,20,19,15,0,0,0:REM              room 16 
3390DATA              0,0,18,0,0,0,0:REM              room 17
3395DATA               14,19,31,17,0,0,0:REM              room 18
3400DATA              18,23,0,16,0,0,0:REM              room 19
3405DATA              16,25,0,0,0,0,0:REM              room 20
3410DATA              15,24,0,32,0,0,0:REM              room 21
3415DATA              0,26,23,0,0,0,0:REM              room 22
3420DATA              19,0,0,22,0,0,0:REM              room 23
3425DATA              21,0,0,0,0,0,0:REM              room 24
3430DATA              20,25,25,25,25,25,0:REM              room 25
3435DATA              22,0,0,0,0,33,0:REM              room 26
3440DATA              0,0,0,0,0,17,0:REM              room 27
3445DATA              0,0,0,0,0,11,0:REM              room 28
3450DATA             4,10,0,0,0,0,0:REM             room 29
3455DATA              30,30,30,30,30,30,0:REM              room 30
3460DATA              31,31,31,31,31,31,0:REM              room 31
3465DATA              32,32,32,32,32,32,0:REM              room 32
3470DATA              43,42,40,0,26,0,0:REM              room 33
3475DATA              0,38,35,0,0,0,0:REM              room 34
3480DATA              0,43,36,34,0,0,0:REM              room 35
3485DATA              0,40,37,35,0,0,0:REM              room 36
3490DATA              37,37,37,37,37,37,0:REM              room 37
3495DATA              34,0,43,39,0,0,0:REM              room 38
3500DATA              0,0,38,0,10,0,0:REM              room 39
3505DATA              36,41,44,33,0,0,0:REM              room 40
3510DATA              40,41,41,42,41,41,0:REM              room 41
3515DATA              33,42,41,42,42,42,0:REM              room 42
3520FOR t=1 TO 1200:NEXT t
3521RETURN
3525DATA              35,33,0,38,0,0,0:REM              room 43
3530DATA              0,0,0,40,0,0,0:REM              room 44
3644IF ro>37 THEN 5096
3645ON ro-19 GOSUB 3650, 3700, 3710, 3720, 3730, 3740, 3750, 3760, 5000, 5010, 5020, 5030, 5040, 5050, 5060, 5070, 5080, 5090
3646RETURN
3650REM                      room 20
3651? " You feel as though you have been wandering around this chataeu for ever..."
3652? " and you begin to dispair of ever escaping...."
3653?:? " Still,you can`t get to depressed, but"
3654? " you must struggle on. Looking around, you see you are in a room which has a"
3655? " heavy timbered ceiling, and white roughly-finished walls..."
3656?:? "There are two doors..."
3657FOR z=1 TO 1000:NEXT z
3659?
3660RETURN
3700REM                     room 21
3701? "  You are in a small alcove. You look around ... but can see nothing in the gloom."
3702? "...Perhaps if you wait a while your eyes will adjust to the murkey darkness...."
3703FOR z=1 TO 2000:NEXT z
3708RETURN
3710REM                     room 22
3711? " A dried up fountain stands in the center of this courtyard,which once held beautiful flowers..."
3712? " ...But have long since died.."
3718RETURN
3720REM                     room 23
3721? " The scent of dying flowers fills this brightly lit room..."
3722? "...There are two exits from it"
3728RETURN
3730REM                     room 24
3731? " This is a round stone cavern"
3732? " off the side of the alcove to your north..."
3738RETURN
3740REM                     room 25
3741? " You are in a enormous circular room, which looks as if it was "
3742? " used as a game room. Rubble covers the floor, partially blocking the only exit "
3748RETURN
3750REM                     room 26
3751? " Throught the dim mustiness of"
3752? " this small potting shed you can"
3753? " see a stairwell..."
3758RETURN
3760REM                     room 27
3761? " You begin this adventure in a small"
3762? " wood outside the Chateau..."
3763FOR z=1 TO 3000:NEXT z
3764?:? " While out walking one day, you come"
3765? " across a small, ramshackle shed in"
3766? " the woods. Entering it,you see a                              hole in one corner...an old ladder"
3767? " leads down from this hole....."
3769RETURN
4141? " Cobwebs brush your face as you make"
4142? " your way through the gloom of this room of shadows"
5000REM                        room 28
5001? " end"
5008RETURN
5010REM                        room 29
5011? " death trap"
5018RETURN
5020REM                        room 30
5021? " pit of flames"
5028RETURN
5030REM                        room 31
5031? " pool of acid"
5038RETURN
5040REM                        room 32
5041? " A giant spider leaps on you... and befor you can react it bites you on the neck... you have 10 seconds to live.."
5042FOR t=10 TO 1 STEP -1
5043? TAB(t); t
5044FOR z=1 TO 300:NEXT z
5045?
5046NEXT t
5047GOTO 2300
5048RETURN
5050REM                        room 33
5051? " A stairwell leads into this room,a"
5052? " poor and common hovel with many"
5053? " doors and exits"
5058RETURN
5060REM                        room 34
5061? " It is hard to see in this room,"
5062? " and you slip slightly on the uneven and rocky floor..."
5068RETURN
5070REM                        room 35
5071? "   HORROR!!!!!"
5072? " This room was once the torture chamberof the chateau"
5073? " ...Skeletons lie on the floor,still "
5074? " with chains on their bones..."
5078RETURN
5080REM                        room 36
5081? " Another room with very unpleasent "
5082? " memories..."
5083FOR z=1 TO 1000:NEXT z
5084?:? " This foul hole was used as the "
5085? "Chateau Dungeon "
5088RETURN
5090REM                        room 37
5091? " This is the Gargoils play room...."
5092FOR z=1 TO 1500:NEXT z
5093? " and you are his toy... too bad!!!! "
5094GOTO 2300
5095RETURN
5096ON ro-37 GOSUB 5101, 5110, 5120, 5130, 5140, 5150, 5160
5098RETURN
5099RETURN
5100REM            **********************
5101REM              room 38
5102? " This was the lower dance hall..."
5103? " With doors to the north,east and west."
5104? " You would seem to be able to flee danger in any direction"
5108RETURN
5110REM                        room 39
5111? " This is the dingy pit at the foot of "
5112? " some extreamly dubious-looking"
5113? " stairs. A door leads to the east..."
5118RETURN
5120REM                        room 40
5121? " Doors open to each compass point from "
5122? " the Trophy room of the Chateau..."
5123?:? " The heads of strange creatures shot"
5124? " hang high on each wall..."
5128RETURN
5130REM                        room 41
5131? " You have stumbled on a secret room..."
5132FOR z=1 TO 1900:NEXT z
5133? " Down here eons ago, the ancient"
5134? " Necromancers of Thorin plied their "
5135? " evil craft...and the remnant of "
5136? " their spells still hangs heavy on the air..."
5138RETURN
5140REM                        room 42
5141? "room of shadows"
5148RETURN
5150REM                        room 43
5151? " This gloomy passage lies at the "
5152? " intersection of three rooms..."
5158RETURN
5160REM                        room 44
5161? "  You are in the rear turret room, below"
5162? "  the extream western wall of the castle..."
5168RETURN
9000? "      HELP SCREEN "
9001?
9002? " t  -  TALLY     "
9003? " n  -  NORTH     "
9004? " s  -  SOUTH     "
9005? " e  -  EAST      "
9006? " w  -  WEST      "
9007? " u  -  UP        "
9008? " d  -  DOWN      "
9009? " q  -  QUIT GAME "
9010? " r  -  RUN AWAY  "
9011? " f  -  FIGHT     "
9012? " i  -  INVENTORY "
9013? " p  -  PICK-UP   "
9014? " m  -  MAGIC     "
9015? " c  -  EAT FOOD  "
9016?
9017?
9018FOR t=1 TO 5000:NEXT t
9019RETURN

