
10REM  ********************
20REM  ***              ***
30REM  ***  AIR ATTACK  ***
40REM  ***              ***
50REM  ********************
55REM  **An Apple Program**
56REM  ** Adapted to the **
57REM  **  Coleco ADAM   **
58REM  ** by W.L. Osburn **
59REM  ********************
60REM  ********************
70REM  ***    12/7/87   ***
80GOSUB 1000:REM INSTRUCTIONS
90GOSUB 2000:REM SET UP
100GOSUB 3000:REM PLAY!
110GOSUB 4000:REM !END!
120END
130REM SL=SHOTS LEFT. YOU MAY MAKE A LONGER GAME   BY GIVING MORE SHOTS IN LINES 1140 & 2030
1000REM 
1010REM INSTRUCTIONS
1020REM 
1030TEXT:HOME:NORMAL
1040VTAB 3:HTAB 11:? "*** AIR ATTACK ***"
1050VTAB 7
1060? "IN THIS GAME YOU ARE A FIGHTER PILOT.  YOU SCORE BY HITTING ONE OF THE ENEMY   SHIPS WITH ONE OF YOUR BOMBS AND SINKINGIT."
1070?
1080? "TO DROP A BOMB, SIMPLY PRESS ANY KEY ONTHE KEYBOARD.  YOUR SCORE FOR HITTING A SHIP WILL DEPEND ON WHICH PART OF THE   SHIP YOU HIT.
1090?
1100? "IF YOU HIT THE LOWER DECK, YOU SCORE   10 POINTS.  IF YOU HIT THE UPPER DECK,  YOU SCORE 20 POINTS.  IF YOU HIT THE    SMOKE-STACK Y
1110VTAB 23
1120INPUT "PRESS *RETURN* TO CONTINUE : "; an$
1130HOME:VTAB 3:HTAB 11:? "*** AIR ATTACK ***":VTAB 7
1140? "YOU HAVE AN ARSENAL OF 15 BOMBS.  THE  SPEED OF EACH SHIP WILL VARY, SO MAKE   EVERY SHOT COUNT! "
1150?:? "GOOD LUCK !!!"
1160VTAB 23
1170INPUT "PRESS *RETURN* TO CONTINUE : "; an$
1180RETURN
2000REM 
2010REM  *** SETUP
2030 sl=15
2040REM LINES 2070 & 2080 DRAW THE WATER
2050GR
2060COLOR =2
2070HLIN 0, 39 AT 39
2080HLIN 0, 39 AT 38
2090 ax=0: sx=33: ss=1
2100RETURN
3000REM RN
3010REM  *** PLAY
3030HOME
3040VTAB 22:? CHR$(24):? "SHOTS LEFT: "; sl; "      SCORE: "; ts
3050GOSUB 3090:REM  PLANE
3060GOSUB 3130:IF sl=0 THEN RETURN
3070GOSUB 3270:REM  SHIP
3080GOTO 3050
3090COLOR =0:HLIN ax, ax+6 AT 2:HLIN ax+1, ax+6 AT 1:PLOT ax+6, 0
3100REM  LINE 3110 CHECKS TO SEE IF THE PLANE IS  AT POSITION -1. IF SO, THE PLANE IS OFF THE        SCREEN. AX REVERTS TO 33, THE RIGHT HA
3110 ax=ax-1:IF ax<0 THEN  ax=33
3120COLOR =4:HLIN ax, ax+6 AT 2:HLIN ax+1, ax+6 AT 1:PLOT ax+6, 0:RETURN
3130IF ff THEN 3160
3140IF PEEK(64885)<128 THEN RETURN
3150 ff=1:POKE 64885, 0: fx=ax+3: fy=2
3160COLOR =0:PLOT fx, fy
3170 fy=fy+1
3180IF SCRN(fx, fy)=0 THEN COLOR =13:PLOT fx, fy:RETURN
3190IF SCRN(fx, fy)=2 THEN 3230
3200 ts=ts+(38-fy)*10
3210 sc=0:COLOR =0:HLIN sx, sx+6 AT 37:HLIN sx+3, sx+5 AT 36:PLOT sx+4, 35
3220 sx=33: ss=1: sc=0
3230COLOR =2:HLIN fx-1, fx+1 AT 37:PLOT fx-2, 36:PLOT fx, 36:PLOT fx+2, 36:PLOT fx-3, 35:PLOT fx, 35:PLOT fx+3, 35
3240COLOR =0:HLIN fx-1, fx+1 AT 37:PLOT fx-2, 36:PLOT fx, 36:PLOT fx+2, 36:PLOT fx-3, 35:PLOT fx, 35:PLOT fx+3, 35
3250 ff=0: sl=sl-1:POKE 64885, 0
3260VTAB 22:? CHR$(24):? "SHOTS LEFT: "; sl; "      SCORE: "; ts
3270 sc=sc+1:IF sc=ss THEN RETURN
3280 sc=0:COLOR =0:HLIN sx, sx+6 AT 37:HLIN sx+3, sx+5 AT 36:PLOT sx+4, 35
3290 sx=sx+1:IF sx>33 THEN  sx=0: ss=INT(RND(1)*3)+1: sc=ss
3300COLOR =1:HLIN sx, sx+6 AT 37:HLIN sx+3, sx+5 AT 36:PLOT sx+4, 35:RETURN
4000REM ***
4010REM  *** END
4030HOME:? "THE GAME IS OVER ":? "YOUR SCORE OF "; ts; " IS "; 
4040IF ts<25 THEN ? "ROTTEN !!!":RETURN
4050IF ts<50 THEN ? "BAD !!!":RETURN
4060IF ts<75 THEN ? "POOR !!!":RETURN
4070IF ts<100 THEN ? "FAIR ...":RETURN
4080IF ts<150 THEN ? "GOOD ...":RETURN
4090IF ts<250 THEN ? "GREAT !!!":RETURN
4100IF ts<450 THEN ? "FANTASTIC !!!":RETURN
