0TEXT:SPEED =255:HOME
1VTAB 10:HTAB 10:FLASH:? "TRAVELER":NORMAL:HTAB 9:FLASH:? " CONCLUSION ":NORMAL:GOSUB 1010
2TEXT:HOME:? "NOW LET'S SEE "; a$; "! NOW WHERE WERE WE!":GOSUB 1005
3GOSUB 10
5GOTO 500
10HGR
12HCOLOR =10
13ROT =0
14DRAW 1 AT 117, 60
15HCOLOR =9
20HPLOT 100, 82 TO 100, 70 TO 110, 55 TO 110, 50 TO 140, 50
25HPLOT 140, 50 TO 140, 55 TO 150, 70 TO 150, 82
35HPLOT 100, 82 TO 110, 95 TO 140, 95 TO 150, 82
55HPLOT 1, 90 TO 149, 90
58HCOLOR =9
60HPLOT 100, 82 TO 145, 82 TO 100, 84 TO 140, 86 TO 90, 88 TO 135, 90
70HCOLOR =2
71HPLOT 200, 62 TO 218, 62 TO 200, 64 TO 218, 66 TO 200, 68 TO 218, 70 TO 200, 72
72HPLOT 105, 88 TO 90, 88 TO 90, 92 TO 106, 92
78HCOLOR =10
90HCOLOR =9
91HPLOT 130, 70 TO 132, 65 TO 130, 60 TO 123, 53 TO 116, 52 TO 110, 53
92HPLOT 150, 70 TO 180, 70 TO 190, 60 TO 220, 60
93HPLOT 190, 60 TO 190, 50 TO 195, 40 TO 200, 38 TO 205, 40 TO 210, 50 TO 210, 60
94HPLOT 220, 60 TO 220, 80 TO 150, 80
96HPLOT 185, 70 TO 215, 70 TO 185, 72 TO 215, 74 TO 185, 76
98HCOLOR =15
99HPLOT 125, 50 TO 120, 42 TO 125, 37 TO 130, 42 TO 125, 50
100HPLOT 125, 50 TO 125, 25
101FOR p=1 TO 2
102HCOLOR =13
104HPLOT 90, 25 TO 160, 25 TO 90, 23 TO 160, 23
106HPLOT 205, 46 TO 195, 55
108HPLOT 195, 46 TO 205, 55
110HCOLOR =9
115HPLOT 130, 53 TO 138, 53 TO 133, 55 TO 140, 60 TO 134, 63 TO 143, 66 TO 134, 68 TO 150, 68
120HCOLOR =9
126HPLOT 145, 82 TO 125, 85 TO 141, 87 TO 125, 90 TO 140, 90 TO 123, 92 TO 137, 92
128HPLOT 110, 92 TO 123, 88 TO 110, 94 TO 125, 94
130HCOLOR =0
131HPLOT 211, 60 TO 216, 61 TO 211, 63 TO 216, 64 TO 211, 66 TO 216, 68 TO 211, 70 TO 216, 72 TO 211, 74 TO 216, 76
140HCOLOR =9
142HPLOT 210, 60 TO 210, 80 TO 208, 60 TO 208, 80
143HCOLOR =0
144HPLOT 105, 85 TO 140, 85
146HPLOT 105, 88 TO 140, 88
148HPLOT 105, 91 TO 137, 91
150HPLOT 114, 56 TO 110, 62
152HCOLOR =12
153FOR m=1 TO 10
154HPLOT 110, 62 TO 115, 63 TO 115, 67
155HCOLOR =13
156HPLOT 105, 10 TO 150, 45 TO 105, 10 TO 150, 45
158HPLOT 140, 98 TO 108, 98
160HPLOT 105, 105 TO 145, 105
164HPLOT 140, 105 TO 140, 90
166HPLOT 110, 105 TO 110, 95
168HPLOT 195, 80 TO 195, 85 TO 200, 88
170HCOLOR =1
178HPLOT 10, 150 TO 80, 120 TO 150, 145 TO 220, 110 TO 249, 150
184HCOLOR =2
188HPLOT 10, 150 TO 80, 120 TO 150, 145 TO 220, 110 TO 249, 150
240HCOLOR =0
241HPLOT 100, 45 TO 145, 10 TO 100, 45 TO 145, 10
242HPLOT 90, 90 TO 40, 90 TO 90, 90 TO 40, 90 TO 90, 90 TO 40, 90
250HCOLOR =3
252HPLOT 165, 20 TO 165, 30
254HPLOT 85, 20 TO 85, 30
256HPLOT 170, 15 TO 170, 35
258HPLOT 80, 15 TO 80, 35
260HPLOT 175, 10 TO 175, 40
262HPLOT 75, 10 TO 75, 40
270HCOLOR =0
274HPLOT 165, 20 TO 165, 30
276HPLOT 85, 20 TO 85, 30
278HPLOT 170, 15 TO 170, 35
280HPLOT 80, 15 TO 80, 35
282HPLOT 175, 10 TO 175, 40
284HPLOT 75, 10 TO 75, 40
288HCOLOR =13
290HPLOT 100, 45 TO 145, 10 TO 100, 45 TO 145, 10
298HCOLOR =12
400NEXT m
405NEXT p
406? "OPPS!! WRONG MACHINE!"
410TEXT:HOME:SPEED =255:RETURN
500TEXT:NORMAL:HOME:SPEED =255
550? "Hi there,...checking status."
560 d$=CHR$(4)
570? d$; "OPEN LOOT"
580? d$; "READ LOOT"
590INPUT a$
595INPUT b$
600INPUT knife$
605INPUT dia$
610INPUT note$
612INPUT key$
615INPUT je$
620INPUT coin$
625INPUT st$
630INPUT pw$
635INPUT ky$
640INPUT ex$
650? CHR$(4)
655? CHR$(4); "CLOSE LOOT"
660GOTO 1200
1000FOR t=1 TO 500:NEXT:RETURN
1001FOR t=1 TO 1000:NEXT:RETURN
1002FOR t=1 TO 2000:NEXT:RETURN
1003FOR t=1 TO 3000:NEXT:RETURN
1004FOR t=1 TO 4000:NEXT:RETURN
1005FOR t=1 TO 5000:NEXT:RETURN
1006FOR t=1 TO 6000:NEXT:RETURN
1007FOR t=1 TO 7000:NEXT:RETURN
1008FOR t=1 TO 8000:NEXT:RETURN
1009FOR t=1 TO 9000:NEXT:RETURN
1010FOR t=1 TO 10000:NEXT:RETURN
1099REM       **** inventory ***
1100IF knife$="KNIFE" THEN ? "KNIFE (silver,jeweled handle)"
1105IF dia$="DIAMOND" THEN ? "DIAMOND (size of egg)"
1110IF note$="NOTE" THEN ? "NOTE (changing messages)"
1115IF key$="KEY" THEN ? "KEY"
1120IF je$="JEWELED EGG" THEN ? "JEWELED EGG"
1125IF coin$="GOLD COIN" THEN ? "GOLD COIN (very old)"
1130IF st$="STATUE" THEN ? "STATUE (rare,&gold)"
1135IF pw$="POWDER" THEN ? "POWDER (for any injury)"
1140IF ky$="GLASS KEY" THEN ? "GLASS KEY"
1145IF ex$="EXPLOSIVE" THEN ? "EXPLOSIVE (of no use now)"
1150IF key$="SILVER KEY" THEN ? "SILVER KEY"
1155IF gun$="GUN" THEN ? "GUN"
1160IF pt$="PORTRAIT" THEN ? "PORTRAIT"
1162IF cr$="CROWN" THEN ? "CROWN"
1163IF dog$="DOG" THEN ? "DOG (following you)"
1165IF ht$="ON" THEN ? "you are wearing the (crown)"
1170IF ring$="RING" THEN ? "RING"
1171IF ro$="ON" THEN ? "(you are wearing the ring.)"
1198RETURN
1200HOME
1210? "THANK YOU "; a$
1220?:?:? "stand by for inventory."
1230GOSUB 1002
1235?:INVERSE:? "YOU ARE CARRYING:":NORMAL:GOSUB 1100
1240GOSUB 1007
1250HOME
1252IF key$="SILVER KEY" THEN  tg$="ALL"
1260HTAB 12:INVERSE:? " STUDIO ":NORMAL
1270?:?:? "A large room once used by some artist."
1275IF pt$<>"PORTRAIT" THEN ? "A (portrait) hangs on one wall"
1276IF dog$="DEAD" THEN ? "A DEAD DOG LIES IN HERE!"
1277?
1280IF chest$="OPEN" AND ring$<>"RING" THEN ? "There is a chest here and it's open.Inside is a ring."
1285IF chest$<>"OPEN" THEN ? "There is a chest here."
1287?
1290IF door$<>"OPEN" THEN ? "There is a small door in one   corner of the room."
1294IF dog$="DEAD" THEN 1300
1295IF door$="OPEN" AND dog$<>"DOG" THEN ? " The small door is open and a  cute little (dog) stands there waging his tail."
1300IF door$="OPEN" AND dog$="DOG" THEN ? "A small open door in one end   of the room(nothing inside)"
1310IF dog$="DOG" THEN ?:? "AN EXIT IS (E)"
1325?:IF tg$="NO" THEN ? "A SILVER (KEY) IS HERE !"
1350?:INPUT "WHAT NOW? "; q$
1360HOME
1365IF q$="TAKE KEY" AND tg$="NO" THEN ? "TAKEN": key$="SILVER KEY":GOSUB 1002:GOTO 1250
1370IF q$="E" AND dog$="DOG" THEN 1500
1371IF q$="E" THEN 1500
1375IF q$="I" THEN INVERSE:? "YOU ARE CARRYING:":NORMAL:GOSUB 1100:GOSUB 1008:GOTO 1250
1390IF q$="USE KEY" AND key$="SILVER KEY" THEN ? "THE CHEST IS NOW UNLOCKED!": chest$="UNLOCKED":GOSUB 1004:GOTO 1250
1394IF q$="TAKE DOG" AND dog$="DEAD" THEN GOTO 1404
1395IF q$="TAKE DOG" AND dog$<>"DOG" THEN ? "HE WILL FOLLOW YOU NOW !": dog$="DOG":GOSUB 1004:GOTO 1250
1400IF q$="KILL DOG WITH KNIFE" THEN ? "DONE,HE IS DEAD!": dog$="DEAD":GOSUB 1004:GOTO 1250
1402IF q$="OPEN CHEST" AND chest$="UNLOCKED" THEN ? "OPEN": chest$="OPEN":GOSUB 1003:GOTO 1250
1404IF q$="OPEN DOOR" AND door$<>"OPEN" THEN ? "OPENED": door$="OPEN":GOSUB 1002:GOTO 1250
1406IF q$="USE KEY" AND key$<>"SILVER KEY" THEN ? "WRONG KEY"
1408IF q$="TAKE PORTRAIT" AND pt$<>"PORTRAIT" THEN ? CHR$(7):? "TAKEN": pt$="PORTRAIT":GOSUB 1002:GOTO 1250
1410IF q$="SHOOT CHEST WITH GUN" THEN  q$="SHOOT"
1412IF q$="SHOOT LOCK WITH GUN" THEN  q$="SHOOT"
1414IF q$="SHOOT CHEST" THEN  q$="SHOOT"
1416IF q$="SHOOT" AND bu>0 THEN ? "BLAM!!": bu=bu-1: chest$="UNLOCKED":? "YOU SHOT THE LOCK!":GOSUB 1004:GOTO 1250
1418IF q$="SHOT" THEN  bu=bu-1
1420IF q$="SHOOT" AND bu>0 THEN ? "OUT OF BULLETS!":GOSUB 1003:?
1422IF q$="SHOOT" AND bu<1 THEN ? "OUT OF BULLETS!":GOSUB 1003:GOTO 1250
1424IF q$="SHOOT DOG" OR q$="SHOOT DOG WITH GUN" THEN  q$="SHOT"
1426IF q$="SHOT" AND dog$="DOG" THEN ? "BLAM,dog is dead": bu=bu-1: dog$="DEAD":GOSUB 1003:GOTO 1250
1428IF q$="COUNT BULLETS" OR q$="COUNT AMUNITION" THEN ? "BULLETS="; bu:GOSUB 1003:GOTO 1250
1430IF q$="TAKE RING" AND ring$<>"RING" THEN  q$="OK"
1432IF q$="OK" AND chest$="OPEN" THEN ? CHR$(7):? "TAKEN": ring$="RING":GOSUB 1002:GOTO 1250
1436IF q$="USE KEY" AND key$="SILVER KEY" THEN  q$="YES"
1438IF q$="YES" AND chest$<>"UNLOCKED" THEN  chest$="UNLOCKED":? "CHEST UNLOCKED":GOSUB 1004:GOTO 1250
1498? "you can't":GOSUB 1000:GOTO 1250
1500HOME
1502IF q$="SHOOT THE TIGER" THEN  bu=bu-1
1510HTAB 9:INVERSE:? " BUTTON ROOM ":NORMAL
1520?:? "ONLY EXIT IS (W)"
1540? "  There is a strange looking   table in here made of solid    marble.It is circular and has  a panel of button!"
1545IF ti$="DEAD" THEN ?:? "A DEAD TIGER IS IN HERE":?
1550?:? "  A large sign hangs over the  table."
1560?:? "  The buttons on the table are (RED)(PINK)(BROWN)&(GOLD)."
1564INVERSE
1565IF rb$="ON" THEN ? "THE RED BUTTON=ON "
1566IF rb$="OFF" THEN ? "THE RED BUTTON=OFF"
1570IF gb$="ON" THEN ? "THE GOLD=ON "
1571IF gb$="OFF" THEN ? "THE GOLD BUTTON=OFF"
1575IF bb$="ON" THEN ? "THE BROWN=ON "
1576IF bb$="OFF" THEN ? "THE BROWN BUTTON=OFF"
1579IF pb$="OFF" THEN ? "THE PINK BUTTON=OFF"
1580IF pb$="ON" THEN ? "THE PINK=ON "
1581NORMAL
1582IF key$="OK" AND gun$="OK" THEN  tg$="OK":? "A GUN IS LYING ON THE FLOOR.":?
1583IF rb$="ON" AND crown$<>"CROWN" THEN ? "A GOLD (CROWN) LIES ON FLOOR"
1584IF crown$="CROWN" AND gun$="GUN" THEN ?:? "AN EXIT IS NOW IS (S)": et$="S":?
1585?:INPUT "what now wise one? "; q$
1587IF q$="S" AND et$="S" THEN 2500
1590HOME
1598IF q$="READ SIGN" AND ht$<>"ON" THEN ? "FOR NOW THE ONLY SAFE BUTTON   IS #1 :(READ NOTE FOR MORE)":GOSUB 1010:?
1600IF q$="READ SIGN" THEN ? "A WORD TO THE WISE:only they   that (WEAR THE CROWN) may use  this.":GOSUB 1005:GOTO 1500
1610IF LEFT$(q$, 4)="PUSH" AND ht$<>"ON" THEN ? "NOT WITHOUT THE PROPER ATTIRE!": m=8:GOSUB 1004:?
1620IF LEFT$(q$, 4)="PULL" THEN ? "DON'T YOU (PULL) ANYTHING      ANYTHING AROUND HERE BUCKOO!":GOSUB 1005
1625IF rb$="ON" AND gb$="ON" THEN  key$="OK"
1630IF rb$<>"ON" OR gb$<>"ON" THEN  key$="NO"
1635IF bb$="OFF" AND pb$="ON" THEN  gun$="OK"
1638IF tg$="OK" THEN  bu=6
1639IF q$="TAKE GUN" THEN  j=1
1640IF q$="TAKE GUN" AND tg$="OK" THEN  gun$="GUN": tg$="NO":? "TAKEN":GOSUB 1002:GOTO 1500
1655IF q$="WEAR THE CROWN" THEN  q$="WEAR CROWN"
1660IF q$="PUT ON CROWN" THEN  q$="WEAR CROWN"
1661IF q$="SHOOT TIGER" OR q$="SHOOT TIGER WITH GUN" THEN  q$="SHOOT THE TIGER"
1662IF q$="SHOOT THE TIGER" AND bu>0 THEN ? "BANG!,tiger by the tail(dead)": ti$="DEAD": j=4:GOSUB 1008:GOTO 1500
1665IF q$="PUT CROWN ON HEAD" THEN  q$="WEAR CROWN"
1666IF gun$="GUN" THEN  j=j+1
1667IF j=2 THEN ? "A (TIGER) HAS APPEARED AND IS  LOOKING AT YOU LIKE A CHICKEN  LEG!!":GOSUB 1008:?:?
1669IF q$="WEAR CROWN" THEN  crown$="CROWN"
1670IF q$="WEAR CROWN" THEN  ht$="ON":? "YOU ARE WEARING THE CROWN !":GOSUB 1004:GOTO 1500
1671IF j=3 AND ti$<>"DEAD" THEN ? "THE TIGER IS COMING TOWARD YOU FAST !":GOSUB 1005:?:?
1672IF j>4 AND j<7 THEN ? "A WIZARD APPEARS FOR A SECOND  HE LAUGHS AT YOU AND LEAVES!":GOSUB 1007:?:?
1673IF j>4 AND ti$<>"DEAD" THEN ? "THE TIGER GOTCHA !":END:END
1675IF q$="TAKE OFF CROWN" OR q$="TAKE CROWN OFF" THEN  ht$="OFF":? "CROWN IS OFF":GOSUB 1003:GOTO 1500
1680IF q$="PUSH ALL BUTTONS" AND pw$="POWDER" THEN ? "YOU HAVE RECIEVED A BAD ELECTR-ICAL SHOCK!": m=8
1682IF q$="PUSH ALL BUTTONS" AND pw$="POWDER" THEN ? "YOU MAY DIE WITHIN 6 MOVES IF  YOU DON'T HAVE A CURE!!": il$="T"
1690IF il$="T" THEN  m=m-1
1695IF q$="WEAR RING" THEN ? "DONE,it's on your finger":GOSUB 1005:GOTO 1500
1700IF m>6 THEN ? "YOU ARE BECOMING WEAK"
1705IF m=6 THEN ? "THE SHOCK WAS VERY GREAT AND   YOU SLUMP AGAINST THE WALL"
1710IF m=5 THEN ? "IF YOU HAVE THE POWDER THEN    (TAKE POWDER) QUICK OR *****"
1715IF m=4 THEN ? "SOON YOU WILL BE NO MORE!"
1720IF m=2 OR m=3 THEN ? "too late now,the shock has     taken your life.":END:END
1730IF q$="TAKE POWDER" AND pw$="POWDER" THEN  il$="O":? "TAKEN,now you will survive.":GOSUB 1005: pw$="NO":GOTO 1500
1735IF q$="TAKE CROWN" AND crown$<>"CROWN" THEN ? CHR$(7):? "TAKEN ,royal one": crown$="CROWN":GOSUB 1004:GOTO 1500
1738IF q$="SHOOT DOG WITH GUN" AND dog$="DOG" THEN  dog$="DEAD":? "POW!,dog gone": bu=bu-1:GOSUB 1005:GOTO 1500
1740IF q$="PUSH RED BUTTON" AND rb$<>"ON" THEN ? "RED=ON": rb$="ON":GOSUB 1002:GOTO 1500
1742IF LEFT$(q$, 4)="PUSH" AND ht$<>"ON" THEN ?:? "YOUR HEAD IS BARE!!!":GOSUB 1004:GOTO 1500
1745IF q$="PUSH RED BUTTON" AND rb$="ON" THEN  rb$="OFF":? "RED=OFF":GOSUB 1002:GOTO 1500
1750IF q$="PUSH PINK BUTTON" AND pb$<>"ON" THEN  pb$="ON":? "PINK=ON":GOSUB 1002:GOTO 1500
1755IF q$="PUSH PINK BUTTON" AND pb$="ON" THEN  pb$="OFF":? "PINK=OFF":GOSUB 1003:GOTO 1500
1760IF q$="PUSH GOLD BUTTON" AND gb$<>"ON" THEN  gb$="ON":? "GOLD=ON":GOSUB 1001:GOTO 1500
1765IF q$="PUSH GOLD BUTTON" AND gb$="ON" THEN  gb$="OFF":? "GOLD=OFF":GOSUB 1002:GOTO 1500
1770IF q$="PUSH BROWN BUTTON" AND bb$<>"ON" THEN  bb$="ON":? "BROWN=ON":GOSUB 1002:GOTO 1500
1775IF q$="PUSH BROWN BUTTON" AND bb$="ON" THEN  bb$="OFF":? "BROWN=OFF":GOSUB 1001:GOTO 1500
1780IF q$="W" THEN 1250
1785IF q$="READ NOTE" AND gun$<>"GUN" THEN ? "THE RIGHT COMBINATION OF (OFF& ON) WILL PRODUCE A (GUN)":GOSUB 1010:GOTO 1500
1790IF q$="READ NOTE" AND gun$="GUN" THEN ? "TO COUNT YOUR BULLETS IN THE   GUN,enter(COUNT BULLETS)":GOSUB 1010:GOTO 1500
1795IF q$="COUNT BULLETS" THEN ? "YOU HAVE "; bu; " BULLETS LEFT !"; a$:GOSUB 1004:GOTO 1500
1800IF q$="SHOOT DOG" AND gun$="GUN" THEN  q$="YEP"
1805IF q$="I" THEN INVERSE:? " YOU ARE CARRYING:":GOSUB 1003:GOSUB 1100:GOSUB 1010:GOTO 1500
1810IF q$="YEP" AND bu>0 THEN ? "BANG !": bu=bu-1: dog$="DEAD":GOSUB 1002:GOTO 1500
1815IF q$="SHOOT" AND bu<1 THEN ? "OUT OF BULLETS,TURKEY!":GOSUB 1005:GOTO 1500
1820IF q$="SHOOT" THEN ? "BLAM, BLAM": bu=bu-2:? "GOOD GRIEF,you wasted 2,now    you have "; bu; " bullets.":GOSUB 1010
1975? "YOU CAN'T":GOSUB 1001:GOTO 1500
2500HOME:SPEED =255
2510?:? "YOU ARE HEADED SOUTH ! THE     GROUND TREMBLES GREATLY AND    YOU REALIZE THAT SOMETHING     IS AMISS !"
2520GOSUB 1010:?:?:?
2530? "SOON YOU SEE ANOTHER MACHINE !":GOSUB 1005:? "you come near it and see.":GOSUB 1003
3000HGR:GOSUB 3010
3001HCOLOR =3:SCALE =1: y=23
3002FOR x=248 TO 125 STEP -5
3003DRAW 4 AT x, y:XDRAW 4 AT x, y:DRAW 5 AT x, y:XDRAW 5 AT x, y:NEXT x
3004DRAW 5 AT 129, 25
3009GOTO 3110
3010HCOLOR =13
3020FOR i=1/60 TO 8*ATN(1) STEP 1/60
3032HPLOT SIN(i)*90+125, COS(i)*9+12
3033HPLOT SIN(i)*90+125, COS(i)*12+60
3035NEXT
3040HPLOT 35, 13 TO 35, 62
3045HCOLOR =8
3050HPLOT 120, 45 TO 120, 35 TO 117, 35 TO 117, 45 TO 120, 45
3060HCOLOR =14:SCALE =1:ROT =0:DRAW 1 AT 80, 30
3070SPEED =60:? "IT LOOK AS IF YOUR FRIEND "; b$; " CAME TO PICK YOU UP!!":GOSUB 1000
3075?:?:?:?
3080? "I'VE BEEN LOOKING ALL OVER FOR YOU;said your friend "; b$
3085?:?:? "<are you ready to enter or do  you wish to go back?"
3090?:?:?:INPUT "enter (Y) to enter the machine "; q$
3095IF q$="Y" OR q$="y" THEN 3100
3096SPEED =255
3097TEXT:HOME
3098GOTO 1500
3100RETURN
3110HCOLOR =13
3115HPLOT 214, 13 TO 214, 62
3150GOSUB 1003
3155SPEED =255
3160FOR t=1900 TO 1984 STEP 2:? CHR$(7):VTAB 21:HTAB 14:? t:NEXT
3162?:?
3165? CHR$(7):? CHR$(7):VTAB 23:HTAB 14:? "1984"
3170GOSUB 1004:TEXT:HOME
3200HTAB 9:INVERSE:? " LOST ISLAND ":NORMAL
3220?:?:? "THIS IS THE END OF THE GAME!   STAND BY AND I WILL CHECK YOUR SCORE ."
3230GOSUB 1007
3240HOME
3245SPEED =90
3250HTAB 8:INVERSE:? " SCORE FOR "; a$; " ":NORMAL
3260?:?
3265 c=0
3270VTAB 4:IF knife$="KNIFE" THEN ? "KNIFE               10": c=c+10
3275IF dia$="DIAMOND" THEN ? "DIAMOND             30": c=c+30
3280IF coin$="COIN" THEN ? "COIN               -20": c=c-20
3285IF st$="STATUE" THEN ? "STATUE              50": c=c+50
3290IF dog$="DOG" THEN ? "DOG                 20": c=c+20
3295IF gun$="GUN" THEN ? "GUN                 20": c=c+20
3300IF egg$="EGG" THEN ? "EGG                 20": c=c+20
3310IF crown$="CROWN" THEN ? "CROWN               20": c=c+20
3320IF bu>0 THEN ? bu; "BULLETS            (bonus)": bu=bux10: c=c+bu
3330IF ring$="RING" THEN ? "RING                40": c=c+40
3340?:INVERSE:? " A PERFECT SCORE WOULD BE 210 ":NORMAL
3350?:? "YOUR SCORE IS "; c
3400SPEED =255
