windchill
        By Bob Currie
   This program appeared in the ADAM's Leaf of the Edmonton ADAM Users Group and is distributed by ADAM News Network.
   This program determines the wind chill factor for a given temperature and wind speed. The comments about the weather given by the program are reasonable but may not be exact. As is usual when typing in a copyrighted program which appears in a magazine, the acknowledgements should be typed in as well. 
100REM ******************** 
110REM * TRS-80 MODEL III * 
115REM * MICROCOMPUTER * 
117REM * PROGRAM * 
120REM * TO DETERMINE * 
130REM * EQUIVALENT * 
135REM * WIND CHILL * 
137REM * TEMPERATURE FROM * 
140REM * WIND VELOCITY * 
145REM * AND TEMPERATURE * 
147REM * INPUTS * 
150REM * * 
160REM *BY J.L. CRANMER JR* 
170REM * VAN HORN, TEXAS * 
172REM * * 
174REM * PUBLISHED IN * 
176REM * 80 MICRO, JAN/83 * 
178REM * * 
180REM * ADAPTED FOR ADAM * 
182REM * BY BOB CURRIE * 
184REM * EDMONTON, ALBERTA* 
186REM ******************** 
190REM 
200HOME:? 
210? " WIND CHILL FACTOR" 
220? 
230? "TEMPERATURE AND WIND VELOCITY" 
240? "CAN BE ENTERED IN METRIC"; " OR":? "U.S.  UNITS":? 
250? "<1> for metric OR " 
255? "<2> for U.S.":? 
260INPUT a 
270IF a<1 OR a>2 THEN VTAB 11:? " TRY AGAIN":VTAB 11:GOTO 260 
280IF a=1 THEN GOTO 360 
290?:? "ENTER AIR TEMPERATURE IN":? "DEGREES FAHRENHEIT" 
300INPUT tf 
310 tt=(5*(tf-32))/9 
320?:? "ENTER WIND VELOCITY IN":?  "MILES PER HOUR" 
330INPUT vm 
340 v=vm*.447 
350GOTO 400 
360?:? "ENTER AIR TEMPERATURE IN":? "DEGREES CENTIGRADE" 
370INPUT tt 
380?:? "ENTER WIND VELOCITY IN":?  "KILOMETERS PER HOUR" 
390INPUT vv: v=vv/3.6:REM CHANGE KM/HR TO M/SEC FOR CALCULATION 
400 hh=(33-tt)*(10.45+(10*v^.5)-v) 
410IF v<=1.788 THEN ta=tt:GOTO 430 
420 ta=33-(hh/22.034) 
430IF a=2 THEN ft=(9*ta/5)+32 
435 h=hh:IF v<=2.5 THEN h=(33-tt)*(10.45+(10*2.5^.5)-2.5) 
440IF h<=200 THEN a$="HOT" 
450IF h>200 AND h<=400 THEN a$="PLEASANT" 
460IF h>400 AND h<=600 THEN a$="COOL" 
470IF h>600 AND h<=800 THEN a$="VERY COOL" 
480IF h>600 AND h<=1000 THEN a$="COLD" 
490IF h>1000 AND h<=1200 THEN a$="VERY COLD" 
500IF h>1200 AND h<=1400 THEN a$="BITTERLY COLD" 
510IF h>1400 AND h<=2000 THEN a$="OUTSIDE EXPOSURE DIASGREEABLE" 
520IF h>2000 AND h<=2300 THEN a$="OUTSIDE EXPOSURE DANGEROUS" 
530IF h>2300 THEN a$="OUTSIDE SURVIVAL UNCERTAIN" 
540HOME 
550IF a=1 THEN GOTO 610 
560? "OUTSIDE TEMPERATURE IS: ":?  tf; " DEGREES "; "FAHRENHEIT" 
570?:? "WIND VELOCITY IS: ":? vm; " MILES PER HOUR" 
580? 
585 ft=INT(ft) 
590? "EQUIVALENT OUTSIDE TEMPERATURE":? "IS: "; ft; " DEGREES FAHRENHEIT" 
600GOTO 645 
610? "OUTSIDE TEMPERATURE IS: ":?  tt; " DEGREES CENTIGRADE" 
620?:? "WIND VELOCITY IS: ":? vv; " KILOMETERS PER HOUR" 
630? 
635 ta=INT(ta) 
640? "EQUIVALENT OUTSIDE TEMPERATURE":? "IS "; ta; " DEGREES CENTIGRADE" 
645? 
650? "OUTSIDE CONDITIONS ARE:  ":?:INVERSE:? a$:NORMAL 
660?:? "RUN AGAIN? Y/N: "; :INPUT b$:IF b$="y" OR b$="Y" THEN GOTO 200 
680END 
 
HEN a$="VERY 
